Encontrar el valor mínimo mayor a cero en Excel

Encontrar el valor mínimo en Excel es muy sencillo con la función MIN pero hay ocasiones en las que necesitamos excluir el cero y los números negativos que se encuentran en el rango de celdas que estamos evaluando.

En esta ocasión te mostraré tres fórmulas que puedes utilizar para obtener el valor mínimo excluyendo el cero o cualquier número negativo. Debo decirte que el último método utiliza una fórmula matricial y, aunque es un concepto avanzado de Excel, es mi método preferido.

Obtener el valor mínimo con la función BDMIN

El primer método que mostraré utiliza la función BDMIN. Esta función se encuentra en la categoría de funciones de base de datos y devuelve el número menor de una columna de registros.

Para que este método funcione correctamente es necesario cumplir con dos condiciones: la primera es que los datos deben tener un encabezado de columna y la segunda es que debemos tener un rango de celdas con el criterio que deberán cumplir los datos evaluados por la función. Con la siguiente imagen explicaré mejor ambas condiciones:

Encontrar el valor mínimo mayor a cero en Excel

Observa que los datos están contenidos en el rango B1:C10 y la primera fila tiene los encabezados de columna Enero y Febrero y por lo tanto se cumple con la primera condición. Debajo de la columna Enero, en el rango B12:B13 está la condición que será utilizada para dicha columna.

Es obligatorio que el rango que contiene el criterio tenga el mismo encabezado de la columna de datos o de lo contrario la función no podrá aplicar el criterio adecuadamente. En este ejemplo, la celda B1 y la celda B12 tienen el texto Enero y algo similar sucede para la columna Febrero donde la condición está ubicada en el rango C12:C13. No es obligatorio que el rango de condiciones esté por debajo de los datos, sino que puede tener cualquier ubicación dentro de la hoja.

Antes de utilizar la función BDMIN insertaré una fila para ver el resultado que devuelve la función MIN. En la siguiente imagen puedes ver que, para la columna Enero el valor mínimo es el número -1 y para la columna Febrero es el cero.

Valor minimo Excel sin cero

Ahora insertaré una nueva fila en la hoja para utilizar la función BDMIN de la siguiente manera:

=BDMIN(B1:B10, "Enero", B15:B16)

El primer argumento de la función son los datos que vamos a evaluar incluyendo el encabezado de columna. El segundo argumento es el nombre de la columna evaluada y el tercer argumento es el rango con la condición. En la siguiente imagen puedes observar el resultado de esta fórmula el cual nos indica que, en la columna Enero, el valor mínimo mayor a cero es el número 3:

Calcular el mínimo distinto de cero en Excel

La función BDMIN utiliza el criterio “>0” (mayor a cero) indicado en la celda B16 y nos devuelve el valor mínimo correspondiente. Al aplicar una fórmula similar en la columna Febrero obtenemos el siguiente resultado:

Excluír el cero del valor mínimo en Excel

La función BDMIN nos devuelve el número 2 que es el valor mínimo mayor a cero en la columna Febrero. Es probable que en algunas ocasiones no puedas tener encabezados de columna en los datos o que no puedes destinar una celda para contener el criterio requerido por la función BDMIN. Si ese fuera el caso, puedes considerar el uso de la función K.ESIMO.MENOR para obtener el mismo resultado y cuyo procedimiento explicaré a continuación.

Fórmula para hallar el valor mínimo mayor a cero

La función K.ESIMO.MENOR nos devuelve el enésimo valor más pequeño del rango. Por enésimo nos referimos a cualquier posición que le indiquemos a la función en su segundo argumento. Para entender mejor su funcionamiento, considera la siguiente fórmula:

=K.ESIMO.MENOR(B2:B10, 1)

El primer argumento es el rango que contiene los valores numéricos que estamos evaluando y el segundo argumento le indica a la función K.ESIMO.MENOR que devuelva la primera posición es decir, el primer valor más pequeño. La fórmula anterior devolverá el mismo resultado que la función MIN como lo puedes ver en la siguiente imagen:

Omitir el cero al calcular el MIN de una lista de valores

Este no es el resultado que necesitamos sino que debemos encontrar la cantidad de valores que sean menores o iguales a cero de manera que podamos pedirle a la función K.ESIMO.MENOR la posición adecuada a devolver. Para descubrir la cantidad de números negativos o iguales a cero en el rango B2:B10 podemos utilizar la función CONTAR.SI de la siguiente manera:

=CONTAR.SI(B2:B10,"<=0")

El primer argumento es el rango de celda que contiene los valores y el segundo argumento es la condición que debe cumplir cada uno de ellos para ser considerado en la cuenta. Si ingresamos esta fórmula en los datos de ejemplo obtendremos el valor 2 porque en dicho rango la celda B7 tiene el número cero y la celda B9 el número -1.

Lo que debemos hacer es utilizar la función CONTAR.SI como el segundo argumento de la función K.ESIMO.MENOR y de esta manera podremos indicarle la posición que ocupa el valor mínimo mayor a cero. Considera la siguiente fórmula:

=K.ESIMO.MENOR(B2:B10, CONTAR.SI(B2:B10, "<=0") + 1)

Al utilizar esta fórmula en nuestros datos de ejemplo obtenemos el resultado mostrado en la siguiente imagen:

Función MIN excluyendo el cero en Excel

La función CONTAR.SI devuelve el valor 2 y a ese resultado le sumamos uno lo cual hace que la función K.ESIMO.MENOR obtenga el tercer valor más pequeño del rango B2:B10 y con eso nos aseguramos de obtener el valor mínimo mayor a cero.

Existe un tercer método para excluir el cero del valor mínimo en Excel y es utilizando una fórmula matricial como lo demostraré en la siguiente sección.

Excluir el cero del valor mínimo con fórmula matricial

Una de las cosas que distinguen a las fórmulas matriciales es la manera en que son ingresadas en la barra de fórmulas. Ya sea que se ingrese por primera vez, o que la fórmula sea editada, siempre se debe terminar con la combinación de teclas Ctrl + Shift + Entrar.

La fórmula que utilizaremos emplea a la función SI para crear una matriz que contenga solamente los valores mayores a cero y por consecuencia, la función MIN nos devolverá el valor mínimo excluyendo el cero o cualquier número negativo que pudiera existir en el rango. La fórmula a utilizar es la siguiente:

=MIN(SI(B2:B10>0,B2:B10))

La función SI evalúa cada uno de los valores en el rango B2:B10, si el valor es mayor a cero devuelve el mismo valor o de lo contrario se devolverá el valor FALSO. De esta manera tendremos una matriz que estará formada solamente de valores positivos o valores FALSO. La función MIN ignorará cualquier valor FALSO y nos devolverá el valor mínimo de los números en la matriz.

La siguiente imagen muestra el resultado de ingresar la fórmula anterior en la celda B13. Recuerda que después de ingresar la fórmula se debe pulsar la combinación de teclas Ctrl + Shift + Entrar.

Hallar el valor mínimo en Excel excluyendo el cero

Ahora conoces tres métodos para encontrar el valor mínimo mayor a cero en Excel. Realiza pruebas con todos ellos y decide por el método que mejor se acomode a tus necesidades y preferencias.

Descargar el archivo de trabajo