Cómo sumar filas alternas en Excel

Hay ocasiones en las que los datos de nuestra hoja han sido organizados de tal manera que necesitamos sumar los valores ubicados en filas alternas.

Lamentablemente no existe una función, o comando, que haga este tipo de cálculo y por lo tanto será necesario crear nuestra propia fórmula que nos ayudará a sumar los valores en filas alternas.

Para nuestro ejemplo, supondremos que nos interesa sumar las filas alternas de los datos que se muestran en la siguiente imagen:

Sumar filas alternas

Existen al menos dos métodos que nos ayudarán a realizar este tipo de suma y los revisaremos a continuación.

Columna Auxiliar para distinguir filas

El primer método que tenemos para sumar las filas alternas implica la creación de una columna auxiliar que nos ayude a distinguir las filas alternas.

Esa columna auxiliar nos ayudará a distinguir entre las filas pares e impares de manera que podamos sumar solo algunas de ellas.

Usaremos la función FILA para obtener el número de la fila en la que nos encontramos, y a ese resultado le aplicaremos la función RESIDUO para saber si estamos en una fila par o impar.

La fórmula que colocaré en la celda I2 quedará de la siguiente manera:

=RESIDUO(FILA(),2)

El segundo argumento de la función RESIDUO indica que obtendremos el residuo de la división entre dos.

De esta manera, si la fila es par, el valor devuelto por la función RESIDUO será cero, por el contrario, si la fila es impar la función RESIDUO regresará el valor uno.

Al copiar esta fórmula en todas las celdas de la columna auxiliar obtendremos el siguiente resultado:

Sumar filas alternas en Excel

Fórmula para sumar filas alternas

Ahora que ya hemos distinguido las filas pares e impares en nuestros datos, podemos utilizar la función SUMAR.SI para sumar aquellos elementos que están en una fila par o impar.

La función SUMAR.SI nos permite evaluar una condición antes de incluir un valor en la suma, y para nuestra primera fórmula, evaluaremos la columna Auxiliar para saber si tiene el valor 0 y en caso de cumplirse dicha condición sumaremos el valor de la columna del mes correspondiente.

Por ejemplo, para sumar las filas de Presupuesto (que están en color azul) para el mes de enero, utilizaré la siguiente fórmula:

=SUMAR.SI($I$2:$I$13,0,C2:C13)

El primer argumento de la función es el rango de la columna auxiliar, la cual utilizaremos como criterio para elegir los valores a sumar. El segundo argumento es el criterio que deben cumplir las celdas de la columna auxiliar para ser consideradas en la suma.

No se sumarán las celdas de la columna Auxiliar, sino que, la función SUMAR.SI nos permite indicar como su tercer argumento el rango de celdas que contiene los valores que serán sumados.

En nuestro ejemplo, las celdas del rango C2:C13 serán sumadas siempre y cuando su valor de la columna Auxiliar sea igual a cero. Al ingresar esta fórmula en la celda C15 obtenemos el siguiente resultado:

Cómo sumar filas alternas en Excel

El número 44085 es la suma de los valores de la columna Enero que se encuentran en las filas pares de la hoja (filas azules). Si quisiéramos hacer la suma de los valores en las filas impares (filas amarillas) podríamos modificar nuestra fórmula de la siguiente manera:

=SUMAR.SI($I$2:$I$13,1,C2:C13)

La única diferencia con la fórmula anterior es que el segundo argumento de la función SUMAR.SI es el número 1 que le pide a la función incluir solo aquellas filas cuyo valor en la columna auxiliar sea igual a uno. Al utilizar esta fórmula en la celda C16 obtenemos el siguiente resultado:

Sumar filas con condiciones en Excel

Por último, copiaré las fórmulas de las celdas C15 y C16 hacia la derecha para obtener los totales de los siguientes meses.

Fórmula para sumar filas alternas en Excel

De esta manera hemos logrado sumar los valores en filas alternas en Excel utilizando una columna auxiliar y la función SUMAR.SI.

En estricto sentido, el método mostrado no está limitado a sumar filas alternas, sino que podrías crear diferentes tipos de criterios para pedir a la función que sume solamente aquellos valores que cumplen con la condición establecida.

Fórmula matricial para sumar filas alternas

El segundo método que podemos utilizar para sumar filas alternas es con una fórmula matricial. Es importante mencionar que este método es recomendable solo para usuarios que ya están familiarizados con el uso de fórmulas matriciales.

Con este método evitaremos el uso de la columna Auxiliar ya que, debido a la naturaleza de las fórmulas matriciales, podremos incluir ese cálculo dentro de la misma fórmula.

Nuestro primer objetivo es obtener una matriz con números 0 y 1 de manera que el número 1 esté ubicado en aquellas filas que deben considerarse en la suma.

La siguiente fórmula matricial nos ayuda a generar una matriz de números 1 para las filas pares de la hoja.

=RESIDUO(FILA(C2:C13)+1,2)

La matriz devuelta por esta fórmula la utilizaremos con la función SUMARPRODUCTO para hacer el cruce con los valores del mes de enero de manera que, al hacer la multiplicación de cada uno de ellos, solo permanezcan los valores multiplicados por 1.

=SUMAPRODUCTO(RESIDUO(FILA(C2:C13)+1,2), C2:C13)

Ingresaré la fórmula anterior en la celda C15 recordando que las fórmulas matriciales se ingresan con la combinación de teclas Ctrl+Shift+Entrar. El resultado es el siguiente:

Fórmulas matricial para sumar filas con condiciones en Excel

Para hacer la suma de las filas impares, solo modificamos un poco la fórmula que genera la matriz de números 1 de la siguiente manera:

=RESIDUO(FILA(C2:C13),2)

La diferencia con la fórmula anterior es que no sumamos 1 al resultado de la función FILA y de esta manera tendremos una matriz de números 1 para las filas impares. Al hacer la combinación con la función SUMARPRODUCTO tendremos la siguiente fórmula:

=SUMAPRODUCTO(RESIDUO(FILA(C2:C13),2), C2:C13)

Ingresaré la fórmula anterior en la celda C16 y tendremos el siguiente resultado:

Fórmula matricial para sumar filas alternas

Puedes copiar las fórmulas a la derecha y compararlas con los resultados del método de la columna Auxiliar y verás que son los mismos.

Los dos métodos que revisamos en esta ocasión nos ayudarán a resolver el problema de sumar filas alternas. El primer método es más sencillo de implementar para los usuarios principiantes.

Por el contrario, el segundo método requiere que estés familiarizado con fórmulas matriciales en Excel ya que podrías obtener continuamente errores al olvidar ingresarlas correctamente.

Moisés Ortiz

Autor: Moisés Ortiz

Moisés es consultor en tecnologías de la información con especialidad en herramientas de inteligencia de negocios y análisis de datos. Tiene más de 25 años de experiencia en el uso de Excel y es una de sus herramientas predilectas para la creación de dashboards y reportes analíticos. Ver más ➤