Cómo obtener la fecha más cercana en Excel

Las fechas son un tipo de dato muy común en las hojas de cálculo y en ocasiones, cuando tenemos un rango de fechas, nos vemos en la necesidad de obtener la fecha más cercana a la fecha actual. En esta ocasión analizaremos las opciones que tenemos para hacer este tipo de búsqueda en Excel.

Antes de mostrar las posibles soluciones, es conveniente recordar que las fechas en Excel son números y es a través del formato de las celdas que los visualizamos como fechas. Es por esta razón que podemos utilizar sin problema alguno las funciones de Excel que generalmente utilizaríamos con valores numéricos. Por ejemplo, en la siguiente imagen puedes observar cómo utilizo la función MIN y la función MAX para obtener la fecha más antigua y la fecha más reciente dentro de un rango de fechas:

Cómo obtener la fecha más cercana en Excel

Las fechas no están ordenadas, pero eso no impide que las funciones devuelvan los valores correctos.

Obtener la fecha más cercana con BUSCARV

Cuando hablamos de realizar búsquedas es prácticamente inevitable considerar a la función BUSCARV ya que es una de las funciones más utilizadas para buscar en Excel. Sin embargo, a diferencia de la mayoría de las ocasiones, no necesitamos que la función BUSCARV haga una búsqueda exacta sino que haga una búsqueda aproximada por lo que utilizaremos de manera diferente el argumento ordenado de la función BUSCARV.

En la mayoría de los casos indicamos el valor FALSO para el cuarto argumento de la función, pero para hacer la búsqueda aproximada indicaremos el valor VERDADERO, por ejemplo:

=BUSCARV(HOY(), A2:A11, 1,VERDADERO)

Con esta fórmula se buscará el valor devuelto por la función HOY que para este ejemplo será el valor “08/07/2014” que es la fecha en que estoy escribiendo este artículo. Pero antes de utilizar esta fórmula es necesario ordenar las fechas de manera ascendente ya que las búsquedas aproximadas con la función BUSCARV funcionarán solamente si los datos están correctamente ordenados. En la siguiente imagen puedes ver que se ha aplicado el ordenamiento y el resultado de la fórmula está en la celda D6:

Buscar el valor más cercano en una lista de Excel

Este resultado nos permite observar que al hacer una búsqueda aproximada con la función BUSCARV obtendremos el valor más cercano anterior. La fecha de hoy es mayor al valor de la celda A4 y menor al de la celda A5, pero la fórmula nos devuelve el valor de la celda A4 así que podemos concluir que al utilizar este método habrá dos implicaciones:

  • Las fechas deberán estar ordenadas de manera ascendente porque la función BUSCARV así lo requiere cuando se hacen búsquedas aproximadas.
  • La función BUSCARV nos devolverá la fecha más cercana anterior.

Si en tu búsqueda por obtener la fecha más cercana en Excel no existe problema alguno en tener estas implicaciones, entonces podrás utilizar este método, de lo contrario será necesario buscar otra alternativa de solución.

Buscar la fecha más cercana anterior sin ordenar datos

Ahora buscaremos alternativas de solución si necesitamos evitar los requisitos impuestos por la función BUSCARV. Para esta opción supondremos que estamos buscando la fecha más cercana anterior a la fecha actual, pero que no podemos ordenar los datos. En ese caso tendremos que utilizar una formula matricial para solucionar el problema.

Para dejar en claro el funcionamiento de esta fórmula, la desarrollaremos en dos pasos y solo por motivos ilustrativos colocaré una fórmula matricial en el rango B2:B11 que comparará el valor de cada celda con la fecha de hoy para saber si es menor:

=SI(A2:A11<HOY(), A2:A11)

Al terminar de ingresar esta fórmula deberás pulsar la combinación de teclas Ctrl + Mayús + Entrar para crear la fórmula matricial (Observación: muchas personas se han acostumbrado a llamar a la tecla Mayús por su nombre en inglés: Shift). Después de introducir la fórmula en el rango indicado obtendremos el siguiente resultado:

Buscar fecha más cercana al día de hoy en Excel

Recuerda que aquí las fechas no están ordenadas, así que podemos ver que las únicas celdas que contienen una fecha anterior a la fecha actual son las celdas A2, A4 y A5. Para obtener la fecha más cercana anterior a la fecha actual, utilizaré la función MAX para obtener dicho valor de la matriz de resultados. La fórmula a utilizar será la siguiente:

=MAX(SI(A2:A11<HOY(), A2:A11))

Esta fórmula es matricial por lo que es necesario pulsar la combinación Ctrl + Mayús + Entrar al terminar de introducirla. Como resultado obtendré la fecha más cercana anterior a la fecha actual, que para nuestro ejemplo es la fecha de la celda A5:

Obtener fecha más cercana dentro de un rango de fechas en Excel

Buscar la fecha más cercana posterior sin ordenar datos

Los dos ejemplos anteriores han encontrado la fecha más cercana anterior a la fecha actual, así que ahora haremos el ejemplo para encontrar la fecha más cercana posterior. La solución será muy similar al ejemplo anterior cambiando el operador de comparación y el uso de la función MIN en lugar de la función MAX:

=MIN(SI(A2:A11>=HOY(), A2:A11))

Esta es una fórmula matricial así que deberá introducirse con la combinación Ctrl + Mayús + Entrar. En este caso estoy utilizando el operador mayor o igual que, así que si dentro de la lista de fechas se encontrara la fecha actual, entonces ese sería el resultado devuelto. Para nuestro ejemplo, la fecha posterior a la actual se encuentra en la celda A10 que es el valor devuelto por la fórmula:

Buscar la última fecha de un rango de fechas en Excel

Recuerda que las fechas de la columna A no están ordenadas y aun así la fórmula encuentra correctamente la fecha más cercana posterior a la fecha actual.

Ejemplo: Encontrar el próximo cumpleaños

Supongamos que tienes una lista en Excel con los nombres de amigos con sus respectivas fechas de nacimiento y queremos saber quién celebrará el próximo cumpleaños a partir del día de hoy.

Fecha cercana a la fecha actual en Excel

El primer paso es crear una columna auxiliar donde podamos obtener las fechas de cumpleaños para el año actual y para eso utilizamos la función FECHA de la siguiente manera:

=FECHA(AÑO(HOY()), MES(B2), DIA(B2))

Esta fórmula generará una nueva fecha con el mismo día y mes de la fecha de nacimiento pero con el año actual.

Cómo se obtiene la fecha más cercana a la fecha actual en Excel

Ahora que ya tenemos las fechas de celebración de cumpleaños para el año en curso, podemos utilizar la fórmula de nuestro último ejemplo para obtener la fecha más cercana evaluando las fechas del rango C2:C10.

=MIN(SI(C2:C10>=HOY(), C2:C10))

Al introducir esta fórmula matricial obtenemos la fecha del próximo cumpleaños a celebrar en este año a partir de la fecha de hoy:

Fecha mayor más próxima a la fecha actual en Excel

Si queremos saber el nombre de la persona que cumple años ese día podríamos utilizar la función BUSCARV pero sería necesario mover la columna Auxiliar a la izquierda de la columna Nombre, pero no deseo hacer ese movimiento así que utilizaré la combinación de funciones INDICE y COINCIDIR para encontrarlo:

=INDICE(A2:A10,COINCIDIR(F2,C2:C10,0))

El resultado será el nombre de la persona que está próxima a cumplir años:

Buscar la fecha más cercana en Excel

Con este ejemplo hemos demostrado que la fórmula propuesta en la sección anterior puede obtener la fecha más cercana en Excel sin necesidad de ordenar las fechas y devolverá la fecha más cercana posterior a la fecha actual.

Moisés Ortiz

Autor: Moisés Ortiz

Moisés es consultor en tecnologías de la información con especialidad en herramientas de inteligencia de negocios y análisis de datos. Tiene más de 25 años de experiencia en el uso de Excel y es una de sus herramientas predilectas para la creación de reportes. Ver más ➤