La función BUSCARV en Excel

La función BUSCARV obtiene su nombre porque hace búsquedas verticales, es decir, busca un determinado valor dentro de una columna de datos y devuelve un valor de una columna diferente, pero de la misma fila que el valor encontrado.

Esta función pertenece al grupo Búsqueda y Referencia el cual tiene otras funciones de búsqueda, pero la función BUSCARV es sin lugar a duda la función más utilizada de todas ellas.

Al indicarle a la función el valor que queremos encontrar, ella se encargará de analizar cada una de las celdas de la columna de búsqueda, desde arriba hacia abajo, y se detendrá al momento de encontrar la primera coincidencia.

Una vez encontrado el valor buscado, la función podrá devolvernos el valor de cualquier columna de los datos siempre y cuando se encuentre en la misma fila del valor encontrado.

La función BUSCARV en Excel

La letra “V” en el nombre de la función BUSCARV nos recuerda que la función realizará una búsqueda vertical, es decir, una búsqueda sobre una columna de los datos.

Aunque el funcionamiento de la función es muy simple, es común que los usuarios de Excel se encuentren con alguna dificultad al momento de utilizarla.

El objetivo de este tutorial es profundizar en los detalles de su uso de manera que te conviertas en un experto de búsquedas en Excel.

Preparación de los datos

Es muy importante dar el formato adecuado a los datos antes de realizar una búsqueda con la función BUSCARV ya que, si no cumplimos con los requisitos indicados por la función, no podremos usarla o simplemente obtendremos resultados incorrectos.

Para asegurar un buen funcionamiento, nuestros datos deben cumplir con tres reglas básicas.

  1. Los datos deberán tener un formato tabular, es decir, debemos organizar la información en filas y columnas las cuales podrán tener encabezados.
  2. La columna donde se realizará la búsqueda deberá estar siempre ubicada a la izquierda de la columna que será devuelta como resultado. Dicho de otra manera, la columna con los datos de búsqueda deberá ser la primera columna de los datos.
  3. Si se realiza una búsqueda aproximada, entonces la columna por la que se realizará la búsqueda deberá ordenarse de manera ascendente.

A continuación, hablaré más sobre cada una de estas reglas para dejar en claro la manera adecuada de preparar los datos, así como los posibles errores que se pueden cometer.

Regla 1: Formato tabular de los datos

Cuando hablo de dar un formato tabular a los datos me refiero a asegurarnos que la información esté organizada adecuadamente para permitir las búsquedas verticales.

Algunos usuarios de Excel almacenan la información en un formato que no es tabular y por lo tanto no es posible utilizar la función BUSCARV.

La siguiente imagen muestra un ejemplo donde los datos no tienen un formato tabular y por lo tanto es imposible realizar una búsqueda con la función BUSCARV.

Datos sin formato tabular

Pareciera que los datos mostrados anteriormente fueron preparados para ser impresos desde la hoja de Excel, pero hemos perdido cualquier posibilidad de utilizar la función BUSCARV sobre ellos.

Para corregir el problema, es necesario dar un formato tabular a los datos tal como se muestra a continuación.

Datos con formato tabular en Excel

En este caso, los datos tienen un encabezado en cada columna que es útil para identificar cada una de ellas, sin embargo, no es indispensable colocar dichos encabezados para realizar búsquedas con la función BUSCARV.

Regla 2: Columna de búsqueda a la izquierda

Debes recordar que el orden de las columnas será importante al momento de usar la función BUSCARV.

Esto se debe a que la función siempre realizará la búsqueda sobre la primera columna del rango de búsqueda que hayamos indicado.

Por ejemplo, si tomamos los datos de la imagen anterior y definimos el rango de búsqueda como A2:D11, esto ocasionará que la función BUSCARV realice siempre la búsqueda sobre los valores de la columna A.

Función BUSCARV busca en la columna de la izquierda

En la imagen anterior puedes observar que el rango de búsqueda tiene un borde de color azul y las celdas de la primera columna tienen un fondo gris para recordarnos que la búsqueda se realizará sobre la primera columna.

Este arreglo en los datos nos permitirá buscar un Nombre y obtener como resultado el mismo Nombre, el Apellido, el Teléfono o el Email.

Por el contrario, si definimos nuestro rango de búsqueda como B2:D11, la función hará la búsqueda sobre la columna B.

Cambio en la definición del rango de búsqueda para permitir el uso de la función BUSCARV

Con este rango de búsqueda podremos buscar un Apellido y obtener como resultado el mismo Apellido, el Teléfono, o el Email, pero sería imposible obtener el Nombre porque dicha columna ha quedado fuera del rango de búsqueda.

La única manera de encontrar un nombre basándonos en el apellido es invirtiendo el orden de las columnas como se muestra a continuación.

Cambio en el orden de columnas para el uso de la función BUSCARV

Ahora que la columna Apellido se ha convertido en la primera columna del rango de búsqueda, podremos realizar búsquedas basadas en el Apellido y obtener el Nombre, el Teléfono o el Email.

Con esto podemos concluir que, al momento de preparar los datos, siempre debemos dejar la columna de búsqueda como la primera columna de los datos ya que la función BUSCARV siempre realizará la búsqueda en dicha columna y no hay manera de modificar este comportamiento.

Regla 3: Ordenar datos para búsquedas aproximadas

La tercera regla en la preparación de los datos es solo necesaria cuando realizamos una búsqueda aproximada.

Resulta que la función BUSCARV nos permite hacer búsquedas exactas y búsquedas aproximadas y nosotros podremos elegir cualquiera de esas dos opciones a través del cuarto argumento de la función.

La realidad es que, la mayoría de las veces realizaremos búsquedas exactas, pero si por alguna razón necesitamos hacer una búsqueda aproximada, entonces tendremos que ordenar la columna de búsqueda de manera ascendente o alfabéticamente.

Datos ordenados para búsqueda aproximada

Más adelante hablaremos sobre las búsquedas aproximadas, pero por ahora solo es importante saber que la función nos permite hacer dos tipos de búsqueda.

Sintaxis de la función

Cuando hablamos de la sintaxis de una función, nos referimos a las reglas que definen la secuencia correcta de los argumentos, el tipo de dato que debemos usar y su obligatoriedad.

Argumentos de la función BUSCARV

Para el caso de la función BUSCARV tenemos 4 argumentos y que son los siguientes:

  1. Valor_buscado (obligatorio): En el primer argumento debemos indicar el valor que estamos buscando. Este valor será buscado, de arriba hacia abajo, en la primera columna del rango de búsqueda. Podemos ingresar el valor directamente, ya sea numérico o una cadena de texto, o podemos colocar una referencia a una celda que contenga el valor buscado. La función BUSCARV no hará diferencia entre mayúsculas y minúsculas.
  2. Matriz_buscar_en (obligatorio): El segundo argumento es una referencia que define el rango donde se realizará la búsqueda. La función BUSCARV siempre buscará en la primera columna de dicho rango y el resto de las columnas podrán ser devueltas como resultado.
  3. Indicador_columnas (obligatorio): El tercer argumento es un valor numérico que nos permite indicar la columna que deseamos como resultado en caso de encontrar una coincidencia. Las columnas no son las de la hoja de Excel, sino las columnas del rango indicado en el segundo argumento (Matriz_buscar_en) donde la primera columna tendrá asignado el número 1.
  4. Ordenado (opcional): El cuarto y último argumento de la función BUSCARV es útil para indicar a la función el tipo de búsqueda que deseamos realizar, ya sea una búsqueda exacta o una búsqueda aproximada. El valor FALSO indicará a la función que deseamos hacer una búsqueda exacta mientras que el valor VERDADERO será para realizar una búsqueda aproximada. Si omitimos este argumento, la función BUSCARV asumirá un valor VERDADERO y por lo tanto hará una búsqueda aproximada.

Como puedes ver, la función BUSCARV tiene tres argumentos obligatorios y uno opcional, pero ya que la mayoría de las veces haremos una búsqueda exacta, colocaremos el valor FALSO en el cuarto argumento.

Ejemplos de la función BUSCARV

A continuación, haremos varios ejemplos con la función BUSCARV para tratar de responder la mayor cantidad de preguntas sobre su uso.

Toma el tiempo necesario para realizar cada uno de los ejemplos ya que es la mejor manera de grabar en tu mente los conceptos mostrados.

En la siguiente imagen se muestran los datos con los cuales trabajaremos.

Datos de ejemplo para la función BUSCARV

Los datos son un listado de varios libros y hay cinco columnas para cada fila: Cantidad, ISBN, Precio, Fecha y Título.

Todo parece indicar que estos datos son el detalle de una orden de compra, pero por ahora no nos preocuparemos por eso, simplemente utilizaremos esta información para poner en práctica nuestros conocimientos de la función BUSCARV.

Buscar un valor numérico

El objetivo del primer ejemplo es mostrar que podemos indicar un valor numérico directamente a la función BUSCARV para realizar la búsqueda.

Por ejemplo, al utilizar la siguiente fórmula, estaré pidiendo a la función BUSCARV que obtenga el título del libro cuya cantidad sea igual a 10.

=BUSCARV(10, A2:E6, 5, FALSO)

A continuación, explico cada uno de los argumentos:

  1. Estamos buscando el número 10 en la primera columna de datos, así que podemos ingresarlo directamente en el primer argumento de la función.
  2. El segundo argumento le indicará a la función el rango de datos sin encabezados y que en este ejemplo es A2:E6.
  3. En el tercer argumento le pedimos a la función que nos devuelva la quinta columna del rango de datos y que corresponde a la columna Título.
  4. Finalmente, en el cuarto argumento ingresamos el valor FALSO porque deseamos hacer una búsqueda exacta.

Si colocamos la fórmula en la celda B8 obtendremos un resultado como el que se muestra a continuación.

Ejemplo de la función BUSCARV

De esta manera hemos buscado exitosamente un valor numérico dentro de los datos y hemos obtenido el resultado deseado.

Habrá ocasiones en las que tendremos la necesidad de buscar un valor que ha sido ingresado en otra celda, por ejemplo, si la celda A9 tuviera el valor 10 y ese fuera el valor que necesitamos buscar, entonces nuestra fórmula debería modificarse de la siguiente manera:

=BUSCARV(A9, A2:E6, 5, FALSO)

El único cambio respecto a la formula anterior es que el primer argumento no tiene el valor numérico, sino que contiene la referencia a la celda A9.

La función BUSCARV se encargará de obtener el valor de dicha celda y realizará la búsqueda correspondiente.

En la siguiente imagen puedes ver el resultado de esta nueva fórmula:

Guía de la función BUSCARV en Excel

La única condición para que este método funcione correctamente es que el tipo de dato de la celda que contiene el valor a buscar sea del mismo tipo de dato que las celdas del rango de búsqueda.

En nuestro ejemplo, la celda A9 tiene un valor numérico al igual que las celdas en el rango A2:A6 que es donde se realizará la búsqueda.

Aunque esta aseveración parece un tanto trivial, en realidad es una de las causas más frecuentes de error al usar la función BUSCARV.

Una ventaja de indicar una referencia en el primer argumento de la función BUSCARV es que podemos realizar diferentes búsquedas con la misma fórmula.

Observa la siguiente imagen y notarás que tenemos la misma fórmula en la celda B9, pero ahora tenemos un resultado diferente porque estamos buscando el número 23 en lugar del número 10 de la fórmula anterior.

Cómo utilizar la función BUSCARV

En nuestro ejemplo, la fórmula de la celda B9 realizará la búsqueda de cualquier valor indicado en la celda A9 sin la necesidad de modificar la fórmula.

Por esta razón será muy común encontrar una referencia a una celda en el primer argumento de la función BUSCARV.

Buscar cadenas de texto

Además de buscar valores numéricos, es muy común tener que realizar búsquedas de cadenas de texto.

Para nuestro siguiente ejemplo buscaremos el título del libro basándonos en la columna ISBN de nuestra tabla de datos.

Si quisiera buscar el libro cuyo ISBN sea igual a 978-0307744586 entonces debo utilizar la siguiente fórmula:

=BUSCARV("978-0307744586", B2:E6, 4, FALSO)

Analicemos con detenimiento los argumentos de esta nueva fórmula.

  1. Ya que estamos buscando una cadena de texto, y estoy indicando su valor directamente en la fórmula, es necesario encerrar el valor en comillas dobles o de lo contrario obtendremos como resultado el error #N/A ya que la función trataría de interpretarlo como un valor numérico.
  2. El rango de búsqueda de nuestra fórmula comienza en la celda B2 porque necesitamos que la columna ISBN sea la primera columna del rango de búsqueda.
  3. Con el rango de búsqueda B2:E6 tenemos solo cuatro columnas disponibles y la columna Título es la cuarta columna dentro del rango B2:E6 y por esa razón hemos colocado el número 4 en el tercer argumento.
  4. Finalmente, en el cuarto argumento de la función, indicamos el valor FALSO para pedir una búsqueda exacta.

El resultado de la búsqueda es el siguiente.

Cómo buscar cadenas de texto

Si quisiéramos hacer la misma búsqueda, pero indicando una referencia de celda en el primer argumento de la función, solo debemos asegurarnos de que los valores de las celdas son del mismo tipo.

En la siguiente imagen podrás ver el resultado de dicha búsqueda y notarás que la celda B9 es de tipo texto al igual que las celdas del rango B2:B6.

Explicación y ejemplos de la función BUSCARV

Una manera rápida de comprobar que los datos son de tipo texto es que Excel los alineará automáticamente a la izquierda.

Por el contrario, si Excel identifica el contenido de una celda como un valor numérico, lo alineará automáticamente a la derecha.

Buscar valores en celdas con formato

A continuación, haremos un ejemplo muy interesante porque realizaremos la búsqueda de un Título basado en la columna Precio.

Este ejemplo es diferente a los anteriores porque las celdas de la columna Precio tienen un formato de moneda, así que la pregunta inmediata sería ¿cómo debemos indicar dicho valor en la búsqueda? ¿Cómo debo pedir a la función BUSCARV que encuentre el libro cuyo precio es $10.14?

Para responder adecuadamente a estas preguntas es muy importante saber que en Excel una celda se forma por su valor y su formato.

Lo que generalmente visualizamos en pantalla es la combinación del valor de la celda y el formato aplicado, pero las fórmulas de Excel siempre descartarán el formato y trabajarán solo con el valor de la celda.

Una manera fácil de conocer el valor de una celda es seleccionarla y observar el valor desplegado en la barra de fórmulas.

Por ejemplo, la siguiente imagen muestra la selección de la celda C2 y su valor en la barra de fórmulas.

Buscar un valor con formato en Excel

La celda C2 tiene el valor numérico 24.44 pero, debido al formato aplicado a la celda, lo vemos desplegado en pantalla como $24.44.

Si para nuestro ejemplo estamos buscando el libro que tenga un precio de $10.14, entonces la fórmula que debemos usar es la siguiente:

=BUSCARV(10.14, C2:E6, 3, FALSO)

El resultado de esta fórmula se observa a continuación.

Cómo usar la función BUSCARV

Ahora hagamos una segunda pregunta interesante para este mismo ejemplo: Si deseo indicar una referencia como el primer argumento de la función BUSCARV ¿Cuál debería ser el formato de dicha celda? ¿Debería tener un formato numérico o podría tener el formato de moneda tal como las celdas de la columna Precio?

La respuesta es que no importará el formato de la celda que contiene el valor a buscar ya que, podría tener un formato General o un formato de moneda, la función BUSCARV considerará solo el valor de dicha celda sin importar su formato.

Considera la siguiente fórmula, donde buscaremos de nuevo el Título del libro basándonos en el precio indicado en la celda A9.

=BUSCARV(A9, C2:E6, 3, FALSO)

En la siguiente imagen puedes observar que la celda A9 tiene un formato de moneda y la función BUSCARV devuelve el resultado correcto.

Ejemplos resueltos de la función BUSCARV

Aunque la celda A9 muestra el valor $10.14 en pantalla, la función BUSCARV tomará su valor (sin formato), lo buscará sobre el rango C2:C6 y nos devolverá la columna Título correspondiente.

Justo en la fila de abajo, la fórmula de la celda B10 hace la misma búsqueda, pero tomando como referencia la celda A10 la cual tiene un formato General y nos devuelve el mismo resultado.

Lo que podemos concluir con este ejemplo es que, la función BUSCARV siempre considerará el valor de las celdas y descartará su formato, ya sea para la celda que contiene el valor a buscar o las celdas que conforman el rango de búsqueda.

Cómo buscar fechas

Las fechas son un tipo de dato muy diferente a los demás ya que son valores numéricos que son mostrados en pantalla con un formato especial.

Por esta razón, muchos usuarios de Excel cometen diferentes tipos de errores al trabajar con las fechas ya que algunos intentan usarlas como si fueran cadenas de texto.

Hagamos un ejemplo para mostrarte algunos errores comunes al momento de buscar fechas con la función BUSCARV.

Supongamos que queremos obtener el título del libro cuya fecha de publicación es el 22/01/2002.

Algunas personas intentarían buscar con una fórmula como la siguiente:

=BUSCARV("22/01/2002", D2:E6, 2, FALSO)

Observa que he colocado la fecha encerrada en comillas dobles dando a entender que la estamos tratando como una cadena de texto, sin embargo, nuestra fórmula nos devolverá un error tal como se muestra a continuación.

Cómo buscar fechas en Excel

Como lo he mencionado antes, las fechas en Excel son valores numéricos, por lo que nuestra fórmula no puede encontrar coincidencia alguna entre la cadena de texto indicada en el primer argumento de la función BUSCARV y los valores numéricos de las fechas del rango D2:D6.

Para comprobar lo que acabo de decir, haremos un cambio “temporal” a nuestra tabla de datos.

Selecciona el rango D2:D6 y desde la pestaña Inicio, dentro del grupo Número, abre la lista de formatos disponibles y selecciona la opción General.

Aplicar formato General a fechas para conocer su valor

Puedes notar que cada una de las celdas muestra un número entero donde antes se desplegaba una fecha.

Antes de seguir con nuestro ejercicio, anota el número de la celda D2, que es igual a 37278 y que corresponde a la fecha que estamos buscando.

Seleccionaré de nueva cuenta la opción Fecha corta para regresar el formato de fecha a las celdas del rango D2:D6 y colocaré la siguiente fórmula en la celda B8.

=BUSCARV(37278, D2:E6, 2, FALSO)

La fórmula encuentra el valor numérico 37278, que corresponde a la fecha 22/01/2002, y nos devuelve el resultado correcto tal como lo muestra la siguiente imagen.

Búsqueda basada en una fecha

Este ejemplo nos demuestra que las fechas en Excel son valores numéricos y que solo a través del formato de la celda se despliegan en un formato familiar para nosotros.

Sin embargo, a la función BUSCARV no le interesan los formatos de las celdas y siempre hará las búsquedas usando los valores de las celdas por lo que, al buscar una fecha, será indispensable indicar su valor numérico.

En nuestro ejemplo anterior, cambiamos el formato de las celdas a General para conocer el valor numérico de las fechas de manera que pudiéramos conocer el valor a buscar, pero eso no será necesario cada vez que necesitemos buscar una fecha con la función BUSCARV.

Afortunadamente existe una función de Excel que nos devolverá el valor numérico de cualquier fecha y me refiero a la función FECHANUMERO.

La función FECHANUMERO acepta una fecha en formato texto y nos devuelve el valor numérico de la fecha así que, podemos utilizarla como el primer argumento de nuestra función BUSCARV para obtener el valor deseado.

=BUSCARV(FECHANUMERO("22/01/2002"), D2:E6, 2, FALSO)

La función FECHANUMERO se encarga de obtener el valor numérico para la fecha “22/01/2002” y la función BUSCARV nos devuelve correctamente el Título del libro que corresponde a dicha fecha, tal como se muestra a continuación.

Función FECHANUMERO para obtener valor numérico de la fecha

Podemos comprobar el buen funcionamiento de nuestra fórmula con tan solo cambiar la cadena de texto de la fecha que indicamos a la función FECHANUMERO.

=BUSCARV(FECHANUMERO("16/09/2003"), D2:E6, 2, FALSO)

El resultado de esta nueva fórmula lo observas en la celda B9 de la siguiente imagen:

BUSCARV y fechas en Excel

De la misma manera que lo hemos hecho en los ejemplos anteriores, si la fecha que estamos buscando está dentro de otra celda, podemos hacer referencia a dicho valor y no será necesario usar la función FECHANUMERO ya que la función BUSCARV se encargará de obtener el valor adecuado de la fecha.

En la siguiente imagen puedes observar que la función BUSCARV obtiene el valor de las celdas A9 y A10 para comparar ambas fechas con el rango D2:D6 y obtener el resultado correcto.

Aprende a usar la función BUSCARV

La única condición para que la fórmula anterior funcione correctamente es que las celdas A9 y A10 tengan un formato de fecha válido en Excel.

Cómo copiar una fórmula de búsqueda

Al trabajar con Excel será común vernos en la necesidad de copiar la función BUSCARV para realizar búsquedas similares en celdas adyacentes.

Sin embargo, es necesario poner atención al tipo de referencias utilizadas dentro de la fórmula para evitar cualquier error en los resultados.

A continuación, haremos un ejemplo que nos dejará en claro las consideraciones que debemos tener antes de copiar una fórmula de búsqueda con la función BUSCARV.

Para esto utilizaré los mismos datos de los ejemplos anteriores, pero solo tendré las columnas ISBN y Título.

Cómo buscar un valor en Excel

Nuestro objetivo es buscar cada uno de los ISBN de la columna D y obtener el Título correspondiente para colocarlo en la columna E.

En lugar de crear varias fórmulas en cada una de las celdas de la columna E, crearemos una sola fórmula para la celda E2 y la copiaremos hacia abajo para obtener el resultado deseado. La fórmula que utilizaremos será la siguiente:

=BUSCARV(D2, A2:B6, 2, FALSO)

Estos son los argumentos de la fórmula:

  1. El primer argumento de la función BUSCARV es la celda D2 que contiene el ISBN que estamos interesados en buscar.
  2. El segundo argumento indica el rango que contiene los datos sobre los cuales haremos la búsqueda y que se encuentra en el rango A2:B6.
  3. El tercer argumento le indica a la función BUSCARV que, una vez que encuentre el ISBN indicando, necesitaremos que nos devuelva la segunda columna del rango de búsqueda que corresponde a la columna Título.
  4. Terminamos la fórmula con el valor FALSO porque queremos una búsqueda exacta.
Cómo copiar una fórmula de búsqueda

Como puedes ver en la imagen anterior, la búsqueda es exitosa y la función BUSCARV nos devuelve el título del libro que coincide con el ISBN indicado en la celda D2.

Para copiar esta fórmula en las celdas inferiores “arrastraré” el borde inferior derecho de la celda E2 hacia abajo.

Si no estás familiarizado con esta técnica de copiado, puedes simplemente seleccionar la celda E2 y pulsar el botón Copiar de la pestaña Inicio y posteriormente seleccionar el rango E2:E7 y pulsar el botón Pegar.

Para cualquiera de los métodos de copiado que utilices, el resultado será el error #N/A tal como se muestra en la siguiente imagen.

Error al copiar una fórmula de búsqueda

Absolutamente todas las celdas muestran el error #N/A indicándonos que la función BUSCARV no ha podido encontrar coincidencia alguna.

Si bien es cierto que, no todos los ISBN de la columna D están enlistados en la columna A, existen algunos otros que sí existen como es el caso de la celda D4 que contiene el mismo ISBN que la celda A3, pero la función BUSCARV indica que no lo ha encontrado.

El error que tenemos en este ejemplo, y que es algo que sucede frecuentemente a los usuarios nuevos de la función BUSCARV es que olvidamos que, al momento de copiar una fórmula a otras celdas, Excel adaptará automáticamente todas las referencias relativas en base a la nueva ubicación de la fórmula.

En nuestro ejemplo en particular, lo que afecta el resultado es el segundo argumento de la función BUSCARV.

En la imagen anterior, la cual muestra los errores #N/A de las celdas, también puedes ver la fórmula copiada a la celda E2 donde el segundo argumento de la función BUSCARV tiene el rango A3:B7 cuando la fórmula original tenía el rango A2:B6.

Esto sucede porque hemos copiado la fórmula hacia abajo y Excel modificó la fila para la referencia del rango de búsqueda y si revisas el segundo argumento de la función BUSCARV de las fórmulas que acabamos de copiar verás que en todos los casos será un rango diferente.

La fórmula de la celda E2 busca sobre el rango A2:B6 y la fórmula de la celda E10 hace la búsqueda sobre el rango A10:B14 el cual está vacío y por lo tanto no encuentra ningún valor a pesar de que el ISBN de la celda D10 se encuentra entre los datos de la tabla original.

Este problema se resuelve si “fijamos” el rango de búsqueda en todas las fórmulas de manera que todas busquen sobre los mismos datos.

Para lograr este comportamiento debemos convertir la referencia del segundo argumento en absoluta y eso lo logramos usando el símbolo $.

La fórmula que ingresaremos en la celda E2 será la siguiente:

=BUSCARV(D2, $A$2:$B$6, 2, FALSO)

Si comparas esta nueva fórmula con la original, verás que el único cambio está en el segundo argumento de la función.

Donde antes había colocado el rango A2:B6 ahora aparece la referencia como $A$2:$B$6 que se refiere al mismo rango de celdas anterior pero le estamos pidiendo a Excel que no modifique dicho rango aun cuando la fórmula sea copiada a otra celda.

En estricto sentido sería suficiente con indicar la referencia como A$2:B$6 ya que solamente copiaremos la fórmula hacia abajo y queremos dejar fijos los números de las filas, pero por ahora dejaré el símbolo $ tanto en las letras de las columnas como en los números de las filas.

La siguiente imagen muestra el resultado después de haber ingresado la nueva fórmula en la celda E2 y después de haber copiado la fórmula hacia abajo.

Copiado exitoso de la función BUSCARV

Observa que siguen existiendo errores #N/A de aquellos ISBN que no fueron encontrados, pero ya no es algo que sucede para todas las celdas.

También puedes ver en la imagen anterior que la celda E10, que es la última de la columna, sigue mostrando adecuadamente el rango de búsqueda como $A$2:$B$6 que es el mismo rango indicado en la fórmula de la celda E2.

Con esto comprobamos que, a pesar de haber copiado la fórmula hacia abajo, la referencia al rango de búsqueda se mantiene igual para todas las fórmulas.

La única referencia que Excel cambió automáticamente fue la del primer argumento de la función BUSCARV, pero ese es precisamente el comportamiento que necesitamos ya que son las celdas de la columna D las que necesitamos que cambien fila tras fila para que se realice la búsqueda correcta.

Lo más importante a recordar es que, cuando tengas la necesidad de copiar una fórmula de búsqueda, deberás asegurarte de indicar correctamente las referencias.

Aquellas referencias que necesites que permanezcan sin cambio alguno, deberán ser indicadas como referencias absolutas utilizando el símbolo $.

Para saber un poco más sobre las referencias absolutas y relativas en Excel puedes consultar el artículo Referencias relativas y absolutas en Excel.

La función BUSCARV es una de las funciones más importantes en Excel. Es necesario que dediques tiempo para aprender correctamente su uso y podrás sacar mucho provecho de esta función.