Extraer contenido de una celda en Excel

En ocasiones necesitamos extraer contenido de una celda de Excel para utilizarlo en alguna otra fórmula o simplemente porque simplemente necesitamos una parte de la cadena de texto contenida en la celda.

Extraer caracteres al inicio o al final

Si necesitas extraer un número determinado de caracteres que se encuentran al inicio o al final de una cadena de texto podemos utilizar la función IZQUIERDA o la función DERECHA. Observa el siguiente ejemplo que extrae los primeros 5 caracteres de la cadena de texto en A1:

Extraer caracteres a la izquierda en Excel

En este ejemplo utilice la función IZQUIERDA pero puedo utilizar la función DERECHA para extraer los últimos 4 caracteres de la misma cadena:

Extraer caracteres a la derecha con Excel

Extraer caracteres intermedios

Si por el contrario, necesitas extraer sólo una parte que se encuentra en medio de la cadena de texto, podemos utilizar la función EXTRAE que nos permite indicar la posición inicial dentro de la cadena donde se iniciará la extracción y adicionalmente la cantidad de caracteres que deseamos extraer.

En el siguiente ejemplo podrás observar que he extraído la palabra “una” especificando a la función EXTRAE que inicie en la posición 14 y obtenga solamente 3 caracteres.

Extraer caracteres intermedios en Excel

Para poder utilizar la función EXTRAE es indispensable conocer la posición inicial donde comenzará la extracción y su longitud en caracteres.

Las tres funciones mencionadas: IZQUIERDA, DERECHA, EXTRAE son las funciones con las cuales podemos extraer contenido de una celda en Excel y a partir de estas funciones básicas podemos hacer combinaciones con otras funciones para otros usos como los que menciono a continuación.

Extraer la primera palabra

Para extraer la primera palabra de una celda utilizamos la función IZQUIERDA junto con la función ENCONTRAR que nos permitirá encontrar la posición del primer espacio en blanco lo cual delimita la primera palabra. La fórmula utilizada es la siguiente:

=IZQUIERDA(A1,ENCONTRAR(" ",A1) -1)

El primer argumento de la función ENCONTRAR es una espacio en blanco y al resultado devuelto le resto el número 1 para poder obtener la longitud correcta de caracteres de la primera palabra. Observa el resultado:

Extraer la primera palabra en Excel

Extraer la última palabra

Para poder extraer la última palabra la situación se complica porque es necesario encontrar el último espacio y a partir de ahí tomar los caracteres de la derecha. Pero para simplificarte el trabajo, esta es la fórmula que obtiene el resultado adecuado:

=ESPACIOS(DERECHA(SUSTITUIR(A1," ",REPETIR(" ",LARGO(A1))),LARGO(A1)))

Esta fórmula devolverá el resultado correcto en nuestro ejemplo:

Extraer la última palabra en Excel

Extraer la n-ésima palabra

Si lo que necesitas es extraer algún número de palabra específica puedes utilizar la siguiente fórmula:

=ESPACIOS(EXTRAE(SUSTITUIR(A1," ",REPETIR(" ",LARGO(A1))), (D8-1)*LARGO(A1)+1, LARGO(A1)))

En esta fórmula el número de palabra se encuentra en la celda D8 por lo que si quiero obtener la segunda palabra debo colocar el valor 2 en dicha celda. Observa el ejemplo:

Extraer cualquier palabra en Excel

Artículos relacionados
Contar palabras en Excel
Extraer información de una fecha en Excel

104 pensamientos en “Extraer contenido de una celda en Excel

  1. J. Ruben Flores

    Hola de nuevo! hay posibilidad de extraer valores de derecha a izquierda? es decir tengo mi CURP por ejemplo: RONG820601HDFDTL05 pero necesito que quede al extraer DDMMAA no como en el curp AAMMDD o se necesita hacer con dos funciones? Gracias de nuevo.

    1. Moisés Ortíz Autor

      Hola J. Rubén, lo mejor será concatenar el resultado de varias funciones EXTRAE.

  2. Jose Martinez

    Que, disculpa la molestia. Una pregunta: Hay una formula para identificar la ultima posición de una palabra que se repite varias veces ??

    Ejemplo: En la Columna A1 dice “Contenido de una celda=1, Contenido de una celda=2, Contenido de una celda=3″

    Me interesaria saber la posicion de la ultima palabara llamada Celda, en este caso para saber cual es el valor que tiene ( =3 ). Los valores que se le dieron a la palabra Celda puedes ser muy diferentes o no pueden llevar un orden (Contenido de una celda=22050, Contenido de una celda=428, Contenido de una celda=5600) pero solo necesitaria identificar cual es la ultima posicion de la palabara “Celda”.

    Muchas gracias y disculpa la molestia

    1. Moisés Ortíz Autor

      Hola José, para encontrar la posición de la última ocurrencia de una palabra en una cadena de texto utiliza la siguiente fórmula:
      =ENCONTRAR(“@”,SUSTITUIR(A1,B1,”@”,(LARGO(A1)-LARGO(SUSTITUIR(A1,B1,””)))/LARGO(B1)))

      Ten en cuenta las siguientes suposiciones de esta fórmula:
      1. La cadena de texto original está en A1
      2. La palabra que buscas está en B1
      3. El texto original no contiene el caracter @. En caso de que lo tuviera, reemplaza de la fórmula el valor “@” con otro caracter que no exista en el texto original.

  3. Carlos

    Una pregunta, tengo una formula para encontrar en un cierto texto, una palabra y devuelve un valor, esta es mi formula, =SI(ESNUMERO(ENCONTRAR(“HZY”,A10)),” BRUMA”, ” -”) esto me dice que en la celda A10, encuentra la palabra HZY devuelve el valor de “BRUMA”, pero si no la encuentra devuelve el valor “-”, entonces mi pregunta es, como puedo hacer para que me busque 2 palabras en el mismo texto, y no solo una, necesito encontrar en ese texto la palabra “HZ” y “HZY” pero no encuentro la form, podrias ayudarme???

    1. Moisés Ortíz Autor

      Hola Carlos, esto se resuelva con un SI anidado:
      =SI(ESNUMERO(ENCONTRAR(“HZY”,A1)),”BRUMA”, SI(ESNUMERO(ENCONTRAR(“HZ”,A1)),”BRUMA”, “-”))

      Lee un poco mas sobre el SI anidado en Excel:
      http://exceltotal.com/funcion-si-anidada/

  4. cniemes

    Aquí te pongo una fácil: En una columna, cada celda contiene un párrafo en que me indica el código de un cliente con formato 1.12465123 , una lista de productos, el valor comprado en $123.45 , y luego comentarios. Deseo extraer a las celdas de al lado el código del cliente y el valor comprado. En cada celda el orden de las palabras es distinto por lo que no puedo ubicar siempre en el mismo sitio los valores que deseo extraer. Ejemplo del texto:
    El día de ayer Fernando Fernández 1.12465123 llevó tres sillas y una mesa y un mantel por valor de $123.45. Se fue muy contento con el color del mantel.
    Es esto posible?

    1. Moisés Ortíz Autor

      Hola cniemes, lo mejor es implementar una búsqueda “personalizada” a través de una macro. Un tema que no podría describir en un solo comentario.

  5. Alex

    Tengo un caso muy interesante, necesita sacar las primeras 5 letras si la palabra es de 6 letras pero si es de 7 letras necesito las primeras 6

    1. Moisés Ortíz Autor

      Hola Alex, utiliza la siguiente fórmula:
      =SI(LARGO(A1)=6,IZQUIERDA(A1,5), SI(LARGO(A1)=7, IZQUIERDA(A1,6)))

  6. Oscar Vicente

    Mi consulta: Es posible construir una fórmula para extraer de una celda (con textos y un número) el número presente del cual no se la ubicación ya que varía de celda a celda ya que no se encuentra normalizada?.
    EJ: “DISEÑO DE UNA PLANTA PILOTO DE PRODUCCION DE COLORANTES NATURALES 852452329566 SANDRA PATRICIA ZAPATA” para obtener en otra celda el valor 852452329566

  7. Andrés

    Estimado: tengo la siguiente duda, si tengo una cantidad de datos por ejemplo en las celdas:
    A1 = 123 horas
    A2 = 1.354 horas
    A3 = 31.456 horas

    Como puedo extraer solo los números y eliminar el texto “horas”??.

    Muchas gracias!

    1. Moisés Ortíz Autor

      Hola Andrés, el ejemplo que puedes leer en este artículo que se refiere a extraer la primera palabra debe funcionar para tu problema ya que solo necesitas hacer la extracción hasta el primer espacio.

  8. Edgar

    Buen día, puedo extraer solo los numero de un codigo, el detalle es que no siempre son las mismas posiciones, ejemplo:
    311LBV
    4555LN
    4557BN
    B509D
    BR6670

    Espero me puedan ayudar.

    Saludos.

    Edgar Preciado

  9. Lisseth

    hola estan buenos esos consejos me podria ayudar con algo, con la formula extraer , pude extraer esto c$ 400,00 pero ahora en la siguiente celda intento sumar varios de estos datos que extraje pero nome lo suma para nada me manda error. yo quisiera saber si ha y alguna forma de sumar estas celdas q contienen formulas de extraccion. y asi me sumen las cantidades con todo y el simbolo de C$?

    1. Moisés Ortíz Autor

      Hola Lisseth, después de extraer la cadena $400,00 Excel lo interpreta como texto y por lo tanto no puedes incluirlo en alguna operación aritmética. Una solución es multiplicar el valor por 1 de manera que Excel almacene el resultado como número en lugar de texto. Por ejemplo:
      =EXTRAE(A1,10,5) * 1

  10. LADES SERRANO

    necesito sacar los primeros 5 numeros si el nemero es de 6 letras pero si es de 7 numeros necesito los primeros 6 y estoy utilizando la siguiente formula =SI(LARGO(A1)=6,IZQUIERDA(A1,5), SI(LARGO(A1)=7, IZQUIERDA(A1,6))) y me sale error (el excel mio es 2010).

    1. Moisés Ortíz Autor

      Hola Lades, a mi me funciona correctamente tu fórmula. ¿Qué error es el que te devuelve Excel?

  11. Rigoberto

    Tengo un problema Quiero obtener solo los numeros y eliminar las letras de (1PS85, 1PS6) y asi de muchas series ayuda por favor. cual seria la formula-.

  12. Martín

    Hola!! Quisiera saber como extraer la ultima lo qe tenga na cadena despues de la última diagonal, ejemplo:
    Si el texto es: “Cadena1/Cadena2/CAdena3/Cadena4″
    ¿Como podria obtener “Cadena4″?

  13. JUAN

    Hola Moises, muy interesante tu página. Gracias por tu aporte.

  14. MONICA

    Moises, por fa tu ayuda con esta inquietud, mira yo tengo en una celda palabra y numeros pero separados con un signo por ejemplo monica*1285 y lo que yo quiero es que unicamante me salga monica1285 sin el signo…que formula necesitaria aplicar para borrar el signo ya que son como 500 celdas que debo modificar y quiero hecerlo con formula para no hacerlo uno por uno…
    Gracias

    1. Moisés Ortíz Autor

      Hola Monica, puedes utilizar la función SUSTITUIR para reemplazar el signo con un espacio en blanco.
      =SUSTITUIR(“monica*1285″,”*”,””)

  15. Beto

    Hola, tengo este consulta que no me sale:
    Quiero extraer todo el texto después de la x:

    Ridrinal Susp x 120mL

    Lo he intentado varias veces, pero no me sale. Lo que pasa es que las líneas pueden ser más largas o más cortas.
    La equis siempre está entre espacios.

    1. Moisés Ortíz Autor

      Hola Beto, suponiendo que el texto está en la celda A1, utiliza la siguiente fórmula:
      =DERECHA(A1,LARGO(A1) – ENCONTRAR(” x “,A1) – 2)

      1. DIEGO

        Estimado, y como lo hago para que en este mismo caso, me salga lo que esta ANTES de la X?

        1. Moisés Ortíz Autor

          Hola Diego, utiliza la siguiente fórmula:
          =IZQUIERDA(A1,ENCONTRAR(” x “,A1) – 1)

  16. jose adrian

    a mi me funciona excel en muchas cosas

  17. edgar

    HOLA TENGO UNA GRAN PREGUNTA, SE PODRÁ EXTRAER DE UNA CELDA QUE CONTIENE UN TEXTO TODAS LAS PALABRAS ACENTUADAS Y QUE TE LAS PONGA EN UN LISTADO

    1. Moisés Ortíz Autor

      Hola Edgar, es posible pero creando una macro.

  18. Olvis Diaz

    Estan muy buenos los articulo, por fa si me puedes ayudar con esta. Tengo el siguiente texto en una celda – LKDJFLKSJ (CENTRAL) – y solo quiero extaer los datos que estan dentro del parentesis. Esto utilizando la siguiente formula =+MID(A11;SEARCH(” “;A11;2)+2;7) – pero el problema es que tengo otras celdas que tienen distinta extensión como por ejemplo- xxxxxx (MUTUALISTA)- , por lo que esta formula no me esta sirviendo de mucho por que solo me permite sacar la información del primer caso y no de los proximos que viene que tienen distintas extensiones.

    1. Moisés Ortíz Autor

      Hola Olvis, la siguiente fórmula funcionará en todos los casos ya que busca los paréntesis:
      =EXTRAE(A1,ENCONTRAR(“(“,A1)+1,ENCONTRAR(“)”,A1)-ENCONTRAR(“(“,A1)-1)

      Solo coloca las funciones equivalente en inglés. Saludos.

  19. Susana RbLpz

    Hola Moisés,
    quisiera me pudieras ayudar, creo que es algo sencillo pero no lo eh podido encontrar.. quiero extraer de una misma celda los primeros 3 digitos, el digito 14 y los ultimos 2 de todo ese numeral… me ayudaron mucho los ejercicios de arriba pero tendria q hacer una formula de izquierda, una de extraer y una de derecha (todos en diferentes celdas) y posteriormente meter en una cuarta celda un CONCATENAR… hay la posibilidad de que yo pueda obtener esto en una sola formula y/o con algo mas sencillo??

    1. Moisés Ortíz Autor

      Hola Susana, no es necesario que utilices una cuarta celda con CONCATENAR, de hecho puedes hacerlo todo en una sola celda concatenando el resultado de todas las funciones con el carácter &, por ejemplo:
      =IZQUIERDA(…) & EXTRAE(..) & DERECHA(…)

  20. Ludim

    Hola Moisés… espero me puedas ayudar, mi problema es el siguiente:
    Tengo una celda con nombres y apellidos, los espacios que separan el nombre y los apellidos necesito que sean “$”, eso lo puedo hacer con reemplazar, el punto es que cuando una celda tiene dos Nombres no quiero que entre esos nombres este “$” sino únicamente el espacio… ósea que en cada una de las celdas solo necesito que aparezcan dos veces “$” porque es la separación entre los dos apellidos y el nombre… espero haberme explicado y que me puedas ayudar.
    Ejemplo:
    Mejía Hermosillo Ángel Martin
    Mejia$Hermosillo$Angel Martin

    Muchas gracias de antemano.

    1. Moisés Ortíz Autor

      Hola Ludim, esto es excesivamente complicado porque no hay manera de que Excel distinga entre apellidos y nombres. Si tuvieras un apellido compuesto como “De la Mora” rompería cualquier lógica aplicada en una fórmula.
      Si por el contrario puedes garantizar al 100% que todos los apellidos se compondrán de una sola palabra, entonces puedes utilizar la función ENCONTRAR pero modificando su tercer argumento para indicar la posición en la que deseas que se inicie la búsqueda, lo cual será muy útil para encontrar el segundo espacio en blanco. La siguiente fórmula encuentra la posición del segundo espacio en blanco:
      =ENCONTRAR(” “, A1, ENCONTRAR(” “, A1) + 1)

  21. Rafael Vasquez

    Tengo un problema, estoy trabajando con excel, para unos formularios, y tengo varias listas para definir campos cerrados. Pero en algunos campos que van anexo a esas listas, necesito que si elijo una opcion de la lista, en otra celda me salga otro dato por default. Me explico. Si en A1 elijo el pais, en B1 me salga la ciudad automaticamente.

    Gracias,

  22. William

    Hola Moises, puedes ayudarme?
    Como hago para extraer todo el contenido de una celda excepto la primera palabra?
    Lo que pretendo es que desaparezca la primera palabra de la celda, y el resto del contenido quede intacto,
    ejemplo: 63hkjk4h32 casa de huespedes
    quiero desaparecer:63hkjk4h32
    quedarme nada mas con:casa de huespedes

    gracias!!

    1. Moisés Ortíz Autor

      Hola William, utiliza la siguiente fórmula:
      =DERECHA(A1,LARGO(A1) – ENCONTRAR(” “,A1))

  23. Valentina

    Hola Moisés, soy de Chile y agradecería me puedas ayudar con lo sgte:
    Tengo una columna con fechas ingresadas de esta manera: “20130402″. Y necesito dejarlo en formato de fecha dd-mm-aaaa, pero no me resulta cambiando el formato a fecha.
    Por lo que,estpy intentando con la formula EXTRAE para dejarlo sí: 02-04-2013. Pude extraer los caracteres “02″, pero no sé si puedo introducir una fórmula EXTRAE dentro de la misma y además agregando este carácter “-”.

    Gracias.

    1. Moisés Ortíz Autor

      Hola Valentina, utiliza la siguiente fórmula:
      =FECHANUMERO(DERECHA(A1,2) & “-” & EXTRAE(A1,5,2) & “-” & IZQUIERDA(A1,4))

      Esto te dejará el número de serie y solo deberás cambiar el formato de la celda a Fecha.

  24. shirley ayala

    Quiero sacar el comentario de una celda a otra celda, pero sin utilizar copiar celda porque son muchisimos los comentarios

    1. Moisés Ortíz Autor

      Hola Shirley, si la opción Pegado Especial > Pegar > Comentarios no te sirve, entonces solo tendrías la opción de crear una macro para extraer los comentarios.

  25. Gerardo

    HOla Moisés

    Necesito de tu ayuda, tengo la siguiente situación necesito extraer cierta parte se una serie de caracteres por ejemplo el que sigue (M)CNIU BL-CNNGB-005552280-8&(H)EURFLH1340678SRZ de esto basicamente lo que necesito es separar los campos que comienzan desde la (M) y terminan en la & y por otro lado asilar en una celda diferente desde el inicio (H). Existe algo que me permita algo asi? considerando que la cantidad de caracteres puede variar

    1. Moisés Ortíz Autor

      Hola Gerardo, por lo que entiendo es el carácter & el que dividirá la cadena. Siendo así, puedes utilizar las siguientes fórmulas:
      Parte izquierda: =IZQUIERDA(A1, ENCONTRAR(“&”, A1)-1)
      Parte derecha: =DERECHA(A1,LARGO(A1) – ENCONTRAR(“&”, A1))

  26. Ruben Carmona

    Hola Moises, me puedes ayudar, del siguiente texto esta en una celda “CH-2482 FACTURA AB 61318067, IUSACEL, RFC IUS890616RH6 IVA 498.63″ quiero sacar el RFC, pero como son diversos textos similares, cambia la ubicacion del RFC. Se puede extraer el RFC apartir de la palabra “RFC”

    Gracias.

    1. Moisés Ortíz Autor

      Hola Rubén, puedes utilizar la siguiente fórmula:
      =EXTRAE(A1,ENCONTRAR(“RFC”,A1)+4,12)

      Las únicas observaciones son las siguientes: Después de la palabra RFC debe existir un espacio en blanco. El RFC debe constar de 12 caracteres o de lo contrario la fórmula traerá caracteres de la siguiente palabra.

  27. José Ramón

    Hola Moisés,
    Necesito dejar este campo de texto: “1,300,00″ en un campo numérico 1300,00. ¿cómo lo puedo hacer?
    Gracias anticipadas por tu ayuda

      1. José Ramón

        Disculpa Moisés,

        =VALOR(“1,300,00″) y =VALOR(1,300,00) ambas devuelven error #¡VALOR!.
        Al tener dos comas, la función VALOR no sirve.
        NO sé si estoy haciendo algo mal. Disculpa por ello.
        Si me puedes echar una mano te lo agradecería.
        Muchas gracias

        1. Moisés Ortíz Autor

          Hola Jose Ramón, no me había percatado de la segunda coma pero es necesario reemplazarla por un punto y para eso dependerá de cómo están tus datos. Si todos los datos terminan en “,00″ utiliza la función REEMPLAZAR para cambiarlo por “.00″. Si por el contrario algunos tienen valores diferentes como “,35″ o “,55″, etc. entonces es necesario encontrar la última coma y reemplazarla por un punto.

          Para encontrar la posición de la última coma puedes utilizar la siguiente fórmula:
          =ENCONTRAR(“@”,SUSTITUIR(D2,”,”,”@”,(LARGO(D2)-LARGO(SUSTITUIR(D2, “,”,””)))/LARGO(“,”)))

          Para entender mejor cómo obtuve esta fórmula consulta el siguiente artículo:
          http://exceltotal.com/encontrar-la-posicion-de-la-ultima-aparicion-de-una-palabra-en-excel/

  28. Israel

    Buenos días Moises, me podrías ayudar sobre como extraer un simbolo de $ en una cadena de texto como el siguiente ejemplo:
    ABUNDIS$AYALA$JOSE MANUEL
    para que quede así: ABUNDIS AYALA JOSE MANUEL
    Muchas gracias

    1. Moisés Ortíz Autor

      Hola Israel, si el texto está en la celda A1 podrías utilizar la siguiente fórmula:
      =SUSTITUIR(A1,”$”,” “)

  29. sebastian

    Buen día moises.
    disculpa si tengo una celda con tipo de dato personalizada asi [h]:mm:ss
    y al querer extraer los primeros dos digitos[h] me manda un valor entero y no las horas que tengo hay.
    espero y me puedas echar la mano.
    gracias

    1. Moisés Ortíz Autor

      Hola Sebastián, aunque la celda se muestra con un formato [h]:mm:ss en realidad tiene un valor numérico. Para poder extraer las horas es necesario trabajar con el valor desplegado y no con el valor de la celda. Comienza por transformar la hora en texto con la siguiente fórmula:
      =TEXTO(A1,”[h]:mm:ss”)

      Una vez transformado en texto puedes utilizar las fórmulas que ya has construido y obtendrás el resultado correcto.

  30. jaime velazquez

    Buenas tardes ante todo. disculpen las molestias no soy muy bueno en excel, pero ando en eso aprendiendo con un libro que compre. Pero bueno necesito una ayuda o duda me gustaria saber o conocer o aprender como obtener los 3 últimos caracteres de una celda en este caso es un lote, como podría hacerlo ,ejemplo:

    150713-236 que en la otra celda obtenga solo: 236.
    o
    150713236 que en la otra celda obtenga solo: 236.

    No se cual sea la mejor forma, de antemano muchas gracias por su apreciable ayuda.

    1. Moises Ortiz Autor

      Hola Jaime, si siempre vas a extraer los últimos 3 caracteres utiliza la función DERECHA, por ejemplo:
      =DERECHA(“150713-236″, 3)

  31. Raul

    Tengo el siguiente caso:
    Quiero extraer las X primeras palabras de una celda y el espacio final de separacion y quedarme con el resto y no quiero estar contando cuantas letras hay para la funcion extrae.
    ejemplo
    Caramelos de chocolate suizo blanco en papel azul
    Caramelos de chocolate suizo negro en papel rojo

    Quiero extraer las 4 primeras palabras y el espacio en blanco “Caramelos de chocolate suizo ”

    Gracias

    1. Moisés Ortíz Autor

      Hola Raul, el truco está en encontrar el tercer espacio en blanco dentro del enunciado y para eso puedes anidar varias veces la función ENCONTRAR. Si el texto está en la celda A1, la fórmula a utilizar es la siguiente:
      =IZQUIERDA(A1,ENCONTRAR(” “,A1,ENCONTRAR(” “,A1,ENCONTRAR(” “,A1,ENCONTRAR(” “,A1)+1)+1)+1))

  32. ernesto

    Gracias por las soluciones, sin hacerte ninguna consulta ya encontre lo que buscaba.

  33. Charlie

    Excelente forma de explicar, muy clara la información y de buena calidad. No cabe duda que cada día se aprende algo nuevo :)

  34. Candela

    Una consulta, como puedo contar las letras que hay en una fila? Es la matriz de unas encuestas entonces preciso el numero de personas que contestaron a, b o c como puedo hacer para contarlas? Gracias

  35. Pedro Fernandez

    BUENAS TARDES
    Quisiera saber que formula usar para trasladar de una hoja a otra los datos de X celdas. Y al momento de cargar en la nueva hoja, automaticamente se borre de la hoja de origen.. es posible esto..??
    Yo tengo una lista de Productos, de los cuales con la funcion BUSCARV en una nueva hoja filtro los productos que le corresponden a un departamento.. Pero teniendo en cuenta que tengo 4 departamentos, como hago para que al cargar en el 2do departamento un producto X, se borre del primero.. Es como un proceso… si es que me pueden ayudar, les estaria muy agradecido…
    Ejemplo = Proceso de Creacion → Proceso de Montaje → Proceso de Terminado → Empaque → Distribucion

    1. Moisés Ortíz Autor

      Hola Pedro, eso solo es posible a través de una macro.

  36. aram gomez

    estimado, como puedo recatar un dato de otra hoja”nombre completo” darle un largo de 70, y si el dato no llena la casilla que los restante sean blancos, pero la condicion simpre tiene que ser de largo 70, ayuda mister por favor, de antemano muchas gracias.

  37. Emilio

    Hola buenas,

    Me surge una duda:

    Tengo una serie de filas del estilo:

    aula nombre:javier
    aula nombre:javier nombre:tomas
    aula nombre:javier nombre:tomas nombre:roberto

    Me interea extraer solo lo que hay a la derecha de nombre la última vez que aparezca nombre. Lo he intentado con varias fórmulas pero me he liado un poco y no me sale.

    Muchas gracias
    Saludos

    1. Moisés Ortíz Autor

      Hola Emilio, la parte más compleja es encontrar la última aparición de la palabra nombre, aunque por los ejemplos que colocas creo que sería mejor encontrar la posición de los últimos dos puntos (:). Puedes consultar el siguiente artículo para aprender cómo hacerlo:
      http://exceltotal.com/encontrar-caracteres-de-derecha-izquierda-en-excel/

      Una vez que encuentres dicha posición solo deberás extraer los caracteres a su derecha.

  38. Ricky

    Estimado Moises:

    En primer lugar gracias por tus articulos muy educativos. Tengo una consulta que me esta “quemando el coco” :)
    en una de las columnas de mi hoja excel tengo datos como por ejemplo: “0.9 LT-000161-CORALATEX CRIL. VERMELHO CARDINAL LITRO” Necesito extraer todos los caracteres que se encuentran despues del “segundo punto” (es decir desde donde esta el nombre del color, en este caso VERMELHO) y deben extraerse hasta el final pero SIN INCLUIR la ultima palabra (en este caso “LITRO” que en mi hoja de excel, varia porque puede ser “BALDE” “BIGALON” “TAMBOR”, etc. ¿Puedes Ayudarme por favor? muchas gracias de antemano…

    1. Moisés Ortíz Autor

      Hola Ricky, te sugiero dividir el problema en dos partes. Primero, para obtener la cadena de texto después del segundo punto puedes utilizar la siguiente fórmula:
      =ESPACIOS(EXTRAE(A1,ENCONTRAR(“.”,SUSTITUIR(A1,”.”,”@”,1)) + 1,LARGO(A1)-ENCONTRAR(“.”,SUSTITUIR(A1,”.”,”@”,1)) + 1))

      Lo importante a resaltar de esta fórmula es que estoy suponiendo que la cadena de texto está en A1. Además que el carácter “@” no forma parte nunca de la cadena de texto.
      El segundo paso es encontrar la posición del último espacio para saber donde inicia la última palabra. Para encontrar la posición del último espacio puedes utilizar la siguiente fórmula.
      =ENCONTRAR(“@”,SUSTITUIR(B1,” “,”@”,(LARGO(B1)-LARGO(SUSTITUIR(B1, ” “,””)))))

      En esta segunda fórmula estoy suponiendo que la celda B1 tiene el resultado de la fórmula del primer paso. Con esto obtendrás la posición del último espacio y solo restará utilizar la función IZQUIERDA para extraer dicha cantidad de caracteres excluyendo así la última palabra.

  39. Mónica

    hola buena tarde, me parece genial tu aporte, quisiera pedirte que me ayudes;
    tengo una lista importada de texto de apellido paterno, materno y nombre,en una sola celda y las necesito cada una en celdas separadas,ya pude extraer el nombre y el apellido materno, pero no puedo con el apellido paterno, pues al ser apellidos de diferentes largos arrastrar la formula no me ayuda,espero puedas ayudarme. GRACIAS!

  40. carolina

    hola buen dia Moises, espero puedas ayudarme, tengo un lio, deseo obtener informacion de una celda.por ejemplo de la celda:A1 que tiene :

    Document 243, CSCMXEG14002/0055USS9.FP1: Spool-ID 142267-1 owned by 1499559 was printed on CSC0108-P1 through port 10.8.62.56. Size in bytes: 46672. Pages printed: 1. No user action is required.

    deseo que me de en otra columna lo que tiene despues de owned by , es decir que me ponga: 1499559

    1. Moisés Ortíz Autor

      Hola Carolina, utiliza la siguiente fórmula:
      =EXTRAE(A1, ENCONTRAR(“owned by “,A1) + 9, ENCONTRAR(” “, A1, ENCONTRAR(“owned by “,A1) + 9) – (ENCONTRAR(“owned by “,A1) + 9))

      1. carolina

        buen dia Moises, muchas gracias por la respuesta, solo que al colocarla me devuelve 0, valido en el espacio de formula y al poner la parte de: FIND(“owned by”,A1)+9, me da como resultado 69 y al poner el resto de la formula en el siguiente campo me pone 0 y abajo un igual y como resultado “”, sabras a que se debe??? trate de hacer la formula por partes, pero no entiendo que es el 9

        de antemano gracias por el apoyo:)

        1. Moisés Ortíz Autor

          Hola Carolina, el número 9 es la longitud de la cadena “owned by ” y es importante indicarlo en la fórmula para contar a partir del final de dicha cadena. Otra cosa importante es que el texto “owned by ” debe tener un espacio en blanco al final para que todo funcione. Con estos comentarios vuelve a intentar ya que a mi me funcionó correctamente la fórmula.

      2. Karol

        Hola Moisés, si a lo propuesto anteriormente quisiera extraer “142267-1″ o lo que hubiese atras de “owned by”, pero sin saber de ello la longitud del texto.

        1. Moises Ortiz Autor

          Hola Karol, esa es una fórmula un poco más compleja que divido en dos pasos, primero es necesario extraer la cadena hasta la palabra ” owned by” y la palabra que deseamos será la última palabra de dicha cadena de texto. El segundo paso es obtener esa última palabra. Suponiendo que la cadena de texto original está en la celda A1, la fórmula es la siguiente:

          =ESPACIOS(DERECHA(SUSTITUIR(EXTRAE(A1,1,ENCONTRAR(” owned by”, A1)-1),” “, REPETIR(” “,LARGO(EXTRAE(A1,1,ENCONTRAR(” owned by”, A1)-1)))),LARGO(EXTRAE(A1,1,ENCONTRAR(” owned by”, A1)-1))))

          Si quieres leer sobre cómo obtener la última palabra de una cadena de texto, consulta el siguiente artículo:
          http://exceltotal.com/extraer-la-ultima-palabra-de-un-texto-en-excel/

  41. MIGUEL

    como puedo convertir o pasar dos celdas concatenadas y que al copiarles me quede como una palabra o texto

    1. Moisés Ortíz Autor

      Hola Miguel, utiliza el comando Pegado especial > Valores.

  42. Diana

    Hola Moisés.
    Necesito de su ayuda, tengo una serie de varios correos que quisiera separarlos para obtener un listado. ¿Qué fórmula puedo utilizar para obtener de manera separada todos los correos?
    Gracias.

    1. Moisés Ortíz Autor

      Hola Diana, es muy difícil recomendarte algún método sin saber cómo está organizada la información.
      Aún así no es muy común hacer ese tipo de extracciones utilizando fórmulas, sino mas bien herramientas como la importación de texto y la separación de columnas:
      http://exceltotal.com/dividir-texto-en-columnas/

  43. will palacios

    hola, disculpa se puede extraer la penultima palabra; sucede que quiero extraer la penultima de un rango determinado donde no hay el mismo numero de palabras ej.
    Pedro reyes almera 500 pagado
    Andrea torres 300 pagado
    jose ivan ramos pa. 200 debe
    quiero extraer solo la penultima palabra. gracias

    1. Moisés Ortíz Autor

      Hola Will, es posible hacerlo y la parte más importante sería obtener el segundo espacio en blanco a partir de la derecha de la cadena de texto. Tengo un artículo que muestra cómo obtener la última palabra y que puedes tomar como base para desarrollar tu fórmula:
      http://exceltotal.com/extraer-la-ultima-palabra-de-un-texto-en-excel/

  44. Fabian

    Que tal Moises, necesito de tu ayuda como puedo extraer en una sola función un texto de la derecha ejemplos: (Dos mil ciento veinticinco pesos 00/100 M.N.) o (Trescientos mil pesos 25/100 M.N.)me interesa obtener solo los centavos, los campos de la derecha son fijos, ya que a la izquierda varian dependiendo de la cantidad y aunque varian los centavos al final siempre son 12 campos, por eso digo que la derecha no tiene cambios me puedes ayudar.
    ya lo hice separando los doce campos de la derecha y después los dos de la izquierda sin embargo deseo saber si esto se puede realizar en una sola fórmula.
    De antemano gracias

    1. Moisés Ortíz Autor

      Hola Fabian, puedes utilizar la siguiente fórmula:
      =EXTRAE(A1,ENCONTRAR(“/”, A1)-2,2)

  45. Andres Mazariegos

    Tengo una Consulta, como puedo saber que numero de palabra es la que estoy buscando en una celda.
    Ejemplo: Hola mi nombre es Andres
    Como puedo formular para que me diga que la palabra “nombre” es la tercera palabra. (en tal caso que regrese el numero 3).
    gracias

    1. Moises Ortiz Autor

      Hola Andres, esa es una fórmula un poco compleja, pero suponiendo que el texto de ejemplo está en A1 y que la palabra a buscar, en este caso “nombre”, está en la celda B1, la fórmula a utilizar es la siguiente:
      =LARGO(EXTRAE(A1, 1, ENCONTRAR(B1, A1) + LARGO(B1) – 1)) – LARGO(SUSTITUIR(EXTRAE(A1, 1, ENCONTRAR(B1, A1) + LARGO(B1) – 1), ” “, “”)) + 1

  46. karim

    Hola la formula para extraer número de una celda a otra celda me resulta pero al arrastrar la formula copia la mismo
    75264 (Cambia NSO)
    que otra formula puedo usar solo para extraer numero

    1. Moises Ortiz Autor

      Hola karim, no me estoy muy seguro de la fórmula a la que te refieres, pero generalmente eso sucede cuando estás utilizando referencias absolutas.
      No es necesario que cambies de fórmula, sino que cambies las referencias a celdas relativas para que al arrastrar la fórmula Excel modifique adecuadamente dichas referencias.

  47. Gabriela

    Hola Moisés;
    Necesito de un listado de clientas (A1-A12) y sus precios (B1-B12), buscar el precio mas bajo en la columna B y una vez encontrado me devuelva el nombre del cliente que esta a la izuqierda.
    Muchas gracias

    1. Moises Ortiz Autor

      Hola Gabriela, te sugiero utilizar la combinación de funciones INDICE/COINCIDIR y la función MIN para obtener el valor más bajo del rango:
      =INDICE(A1:A12, COINCIDIR(MIN(B1:B12),B1:B12,0))

      Si quieres saber más sobre estas funciones te recomiendo leer el siguiente artículo:
      http://exceltotal.com/formula-para-buscar-datos-en-excel/

  48. luis alberto

    Es posible mediante formulas dividir una columna de nombrrs y apellidos en dos? El problema es que unos apellidos son compuestos y en otros casos los nombres y no se si se puede hacer mediante formulas(izquierda, derecha, hallar, largo) me podrias ayudar.
    Gracias

  49. Juan

    Hola de un dato como el siguiente 6/14/2014 10:12:56 PM
    como separo para que solo me de la fecha, pero que no sea con el formato, ya que este aunque no te muestre la hora sigue con ella y solo necesito los caracteres de la fecha.

    1. Moisés Ortíz Autor

      Hola Juan, suponiendo que dicho valor está en la celda A1, podrías utilizar la función TEXTO de la siguiente manera:
      =TEXTO(A1, “dd/mm/aaaa”)

      Aunque pareciera que tienes la fecha en formato inglés y en ese caso el segundo argumento de la función TEXTO deberá ser “mm/dd/yyyy”.

  50. Nestor

    Tengo un detalle y quisiera ver si me podrian ayudar, tengo una celda con informacion NOMBRE_COMPLETO. DEPARTAMENTO (Mtro. Andres E. Salazar Dzib. Secretario Academico) entonces lo que quiero es separar el nombre del departamento que el nombre completo vaya en una celda y el departamento en otra, como le podria hacer ?