Extraer la última palabra de un texto en Excel

El artículo de hoy surge por la necesidad de un amigo por extraer la última palabra de un texto en Excel. Aunque él mismo empezó a realizar esta tarea porque parecía sencilla a primera vista, terminó sin una solución adecuada. Para obtener el resultado correcto será necesario utilizar varias funciones de Excel.

Cómo extraer la última palabra en Excel

Seguramente encontrarás varios métodos alternos para extraer la última palabra de un texto, pero la alternativa que mostraré en esta ocasión es la que encuentro más sencilla. El primer paso será reemplazar los espacios sencillos del texto original por varios espacios en blanco. Considera la siguiente fórmula:

=SUSTITUIR(A2, " ", REPETIR(" ", LARGO(A2)))

Esta fórmula toma los espacios del texto en la celda A2 y los reemplaza por múltiples espacios en blanco. El número de nuevos espacios insertados dependerá de la longitud del texto original, la cual obtenemos con la función LARGO. Observa la siguiente imagen donde aplico esta fórmula:

Cómo extraer la última palabra de un texto en Excel

El texto de la celda A2 tiene una longitud de 18 caracteres, por lo tanto la función SUSTITUIR reemplazará cada espacio simple por 18 espacios en blanco que serán el resultado de la función REPETIR. De esta manera puedes observar en la celda B2 que entre cada una de las palabras existen 18 espacios en blanco.

Obtener la última palabra del texto

Ahora que tenemos múltiples espacios en blanco entre cada palabra podremos utilizar la función DERECHA para obtener la última palabra. La cantidad de caracteres a extraer de la derecha será la longitud del texto original.

=DERECHA(B2, LARGO(A2))

Si analizamos con detenimiento esta fórmula, sabremos que como resultado obtendremos una cadena de texto que contendrá la última palabra del texto original. Esto lo podemos asegurar porque en el paso anterior insertamos una cantidad de espacios en blanco igual a la longitud de la cadena original por lo que la función DERECHA siempre nos devolverá una cadena de texto formada por espacios en blanco seguidos por la última palabra del texto:

Obtener la última palabra de un texto en Excel

El último paso es utilizar la función ESPACIOS para remover los espacios a la izquierda de la palabra. Observa el resultado:

Extraer la última palabra en Excel

Fórmula para extraer la última palabra

Hemos hecho este procedimiento paso a paso dividiendo el procedimiento en tres fórmulas diferente pero si queremos tener una sola fórmula en nuestra solución, entonces debemos utilizar la siguiente:

=ESPACIOS(DERECHA(SUSTITUIR(A2," ", REPETIR(" ",LARGO(A2))),LARGO(A2)))

Al copiar esta fórmula hacia todas las celdas de las cuales deseo obtener la última palabra tendremos un resultado como el siguiente:

Fórmula para extraer la última palabra de un texto en Excel

De esta manera puedes obtener fácilmente la última palabra de un texto en Excel con la seguridad de que la fórmula que hemos construido obtendrá siempre el resultado correcto.