Función SI con rangos de valores en Excel

Entre todos los ejemplos que encontramos al trabajar con Excel, existe un caso muy especial, y es cuando tenemos varios rangos de números y queremos saber si un valor pertenece a alguno de ellos.

Podemos utilizar la función SI junto con otras funciones para conocer el rango al que pertenece un valor determinado, pero es importante poner mucha atención en la construcción de las condiciones de nuestra fórmula ya que eso es lo que determinará los rangos.

Para nuestro primer ejemplo consideraremos una lista de valores numéricos del 1 al 30. Si el valor es mayor o igual a 10 pero menor que 20, desplegaremos el texto “Verde”. Por el contrario, si el valor es mayor o igual a 20, pero menor a 30, entonces desplegaremos el texto “Azul”.

Función SI rangos valores

Determinar rangos con la función Y

Un rango de valores está determinado por un límite inferior y un límite superior y la función Y es excelente para determinar si un número cumple con ambas condiciones. Lo único que debemos hacer es indicar ambos límites a la función. Por ejemplo, nuestro primer rango es igual o mayor al número 10 pero menor al número 20 y eso lo podemos indicar con la siguiente fórmula:

=Y(A2>=10, A2<20)

En este caso he tomado la celda A2 como ejemplo, y la primera condición compara su valor para saber si es mayor o igual a 10. La segunda condición compara el valor de la celda A2 para saber si su valor es menor a 20.

Solo en caso de que ambas condiciones se cumplan, obtendré como resultado el valor VERDADERO. De lo contrario, la función Y nos devolverá el valor FALSO. La siguiente imagen muestra el resultado de aplicar esta fórmula a una serie de valores numéricos.

Función SI con rangos de valores en Excel

La columna A tiene los valores del 1 al 15 y la columna D los valores del 16 al 30. Solo aquellos valores que cumplen con las dos condiciones del rango definido por la función Y, serán aquellos que nos devolverán el valor VERDADERO. Para definir el segundo rango de nuestro ejemplo, podemos utilizar la siguiente fórmula:

=Y(A2>=20, A2<30)

Al aplicar esta fórmula a nuestra lista de valores numéricos obtendremos el siguiente resultado:

Función SI entre rangos

Observa que el valor 30 despliega el valor FALSO porque la definición de nuestro rango lo excluye por completo al realizar la comparación menor que 30. Ahora que tenemos las fórmulas que definen nuestros rangos, podemos combinarlas con la función SI para obtener los mensajes de texto que necesitamos.

La función SI con rangos

La función SI nos permite evaluar el resultado de una prueba lógica a la vez, pero nuestro ejemplo incluye dos rangos de valores por lo que necesitaremos anidar la función SI para poder realizar la segunda prueba lógica. Pero vayamos paso a paso en la construcción de nuestra fórmula.

En primer lugar crearé la fórmula que nos permitirá saber si el valor se encuentra dentro del rango mayor o igual a 10 y menor a 20 para que devuelva la cadena de texto “Verde”. La fórmula será la siguiente:

=SI(Y(A2>=10, A2<20), "Verde")

Observa que el primer argumento de la función SI es una de las fórmulas que definimos en la sección anterior. El segundo argumento de la función SI devolverá el texto “Verde” en caso de que el valor pertenezca al rango indicado.

Para incluir nuestro segundo rango, utilizaré el tercer argumento de la función SI y colocaré una segunda función SI para determinar si el valor se encuentra en el rango mayor o igual a 20 y menor a 30. La fórmula es la siguiente:

=SI(Y(A2>=10, A2<20), "Verde", SI(Y(A2>=20, A2<30), "Azul", ""))

La función SI que hemos anidado utiliza su tercer argumento para pedir a la fórmula que devuelva una cadena de texto vacía en caso de que el valor no pertenezca a ninguno de los dos rangos. La siguiente imagen muestra el resultado de utilizar esta fórmula con nuestros datos de ejemplo:

Función SI anidada con rangos de datos en Excel

Es así como la función SI anidada, junto con la definición de los rangos de la función Y, nos ayudará a obtener el resultado esperado.

Cuántas funciones SI anidadas debo utilizar

En nuestro ejemplo anterior hay dos rangos para los cuales necesitamos un resultado diferente para cada uno, por esa razón hemos utilizado dos funciones SI anidadas. Ahora imagina que tenemos tres rangos para los cuales queremos el siguiente comportamiento:

Condicionando rangos en Excel con la función SI

El tener un tercer rango donde queremos desplegar el texto “Amarillo” ocasionará que tengamos que emplear una tercera función SI anidada. La fórmula que nos permite solucionar este caso será la siguiente:

=SI(Y(A2>=10, A2<20), "Verde", SI(Y(A2>=20, A2<30), "Azul", SI(Y(A2>=1, A2<10), "Amarillo", "")))

Esta fórmula es muy parecida a la de nuestro ejemplo anterior pero, en el tercer argumento de la segunda función SI, he agregado la nueva función que nos ayudará a evaluar los valores para el rango mayor o igual a 1 y menor a 10. La siguiente imagen muestra el resultado de esta fórmula sobre nuestros datos de ejemplo:

Función SI entre dos valores en Excel

Observa que el número 30 aparece vacío porque dicho valor no cumple con ninguna de las condiciones para pertenecer a alguno de los rangos.

De esta manera podemos concluir que, la cantidad de funciones SI anidadas que debemos utilizar será la misma cantidad de rangos para los cuales necesitamos un resultado diferente. En el ejemplo anterior tenemos tres rangos con resultado diferente y por lo tanto utilizamos tres funciones SI.

Rangos de números discontinuos

Hay ocasiones en las que necesitaremos definir un rango que estará compuesto por números discontinuos, por ejemplo, un rango con los números del 5 al 10, números del 15 al 20 y números del 25 al 30.

Fórmula para rangos en Excel

¿Cómo creamos una fórmula para saber si un valor pertenece a este conjunto de números? La solución comienza por definir de manera individual cada uno de los rangos.

Y(A2>=5, A2<=10)
Y(A2>=15, A2<=20)
Y(A2>=25, A2<=30)

Estas fórmulas definen a los rangos de manera individual y para crear una fórmula que los incluya todos a la vez, utilizaremos la función O de la siguiente manera:

=O(Y(A2>=5, A2<=10), Y(A2>=15, A2<=20), Y(A2>=25, A2<=30))

Ya que la función O nos ayuda a determinar si al menos uno de los argumentos se cumple, entonces obtendremos el valor VERDADERO para aquellos valores que pertenezcan a cualquiera de los rangos indicados.

Ya que la fórmula anterior define el rango de números para el cual deseamos mostrar el mensaje “Verde”, entonces podemos combinarla con la función SI de la siguiente manera:

=SI(O(Y(A2>=5, A2<=10), Y(A2>=15, A2<=20), Y(A2>=25, A2<=30)), "Verde", "")

El primer argumento de la función SI es la definición del rango, el segundo argumento es la leyenda “Verde” que se mostrará en caso de que el valor pertenezca al rango de números discontinuos y en caso contrario se mostrará una cadena de texto vacía. El resultado lo puedes observar en la siguiente imagen:

Fórmula de Excel para intervalos de valores

Una gran cantidad de errores que cometen los usuarios de Excel al utilizar este tipo de fórmulas, se deben a una mala implementación de los rangos. Es importante que tomes el tiempo necesario para definir adecuadamente cada uno de los rangos de manera que la función SI pueda devolver el valor esperado.

Además, es importante tener un uso adecuado de la función SI anidada para implementar adecuadamente la lógica de las fórmulas. Si lo crees conveniente, puedes echar un vistazo a un video donde explico con mayor detenimiento el uso de la función SI anidada.

Comienza a practicar con los ejemplos mostrados en este artículo y pronto podrás crear fácilmente fórmulas condicionales que utilicen rangos de números en Excel.

Moisés Ortiz

Autor: Moisés Ortiz

Moisés es consultor en tecnologías de la información con especialidad en herramientas de inteligencia de negocios y análisis de datos. Tiene más de 25 años de experiencia en el uso de Excel y es una de sus herramientas predilectas para la creación de reportes. Ver más ➤