Encontrar el valor más frecuente en Excel

Cuando tenemos una lista de valores y necesitamos encontrar el valor más frecuente podemos recurrir a la función MODA.UNO que hace precisamente eso, nos ayuda a encontrar el valor que más se repite dentro de un rango de celdas.

La función MODA.UNO

La función MODA.UNO fue introducida en Excel 2010, pero puedes utilizar la función MODA para  versiones anteriores. Esta función recibe como argumentos una lista de valores numéricos de los cuales se obtendrá el valor más frecuente. Por ejemplo, en la siguiente imagen puedes observar que la función MODA.UNO devuelve el valor 1, el cual se repite cuatro veces dentro del rango A1:A10.

Encontrar el valor más frecuente en Excel

Esta función siempre devolverá un solo valor y debemos tener en consideración los siguientes puntos al momento de utilizarla:

  • Los argumentos pueden ser referencias a otras celdas o nombres de rango, pero las celdas deberán contener valores numéricos.
  • Si alguna celda tienen un valor en texto o contiene un error, entonces la función devolverá el error #N/A.
  • Si dentro de la lista no existen valores duplicados, entonces la función devolverá el error #N/A.

Como ya lo he mencionado antes, la función MODA.UNO siempre devuelve un solo valor pero ¿Qué sucede si tenemos dos valores numéricos que se repiten la misma cantidad de veces?

Encontrar el valor que más se repite en un rango de datos en Excel

En el ejemplo anterior, tanto el número 2 como el número 3 se repiten 4 veces cada uno, sin embargo la función MODA.UNO solo nos puede devolver el número 2. Precisamente para resolver esta situación se creó la función MODA.VARIOS.

La función MODA.VARIOS

La función MODA.VARIOS es una función que nos devolverá múltiples valores por lo que debemos utilizarla como una fórmula matricial, es decir pulsando la combinación de teclas Ctrl + Mayús + Entrar al final de la fórmula. Pero antes de ingresarla debemos seleccionar el rango de celdas donde deseamos obtener los resultados. Para nuestro ejemplo seleccionaré el rango C1:C2:

Cómo encontrar el valor más repetido en Excel

Posteriormente en la barra de fórmulas introduciré la fórmula sin pulsar entrar:

=MODA.VARIOS(A1:A10)

Finalmente pulsaré la combinación de teclas Ctrl + Mayús + Entrar. Es importante mencionar que la tecla Mayús es también conocida por su nombre en inglés como la tecla Shift. Una vez ingresada la fórmula matricial, Excel desplegará los resultados en el rango previamente seleccionado:

Valores más frecuentes en un matriz de Excel

A diferencia de la función MODA.UNO, la función MODA.VARIOS devuelve como resultado los valores que más se repiten dentro del rango indicado, que en este caso son los números 2 y 3. En este ejemplo hice una selección previa del rango C1:C2 pero en realidad eso no tiene relevancia, ya que si hubiera seleccionado una mayor cantidad de celdas, pero la fórmula no devuelve tantos resultados, entonces dichas celdas mostrarían el error #N/A sin afectar el resultado de la función:

Valores más frecuentes en un rango con la función MODA.VARIOS

Recuerda que la función MODA.VARIOS está disponible solamente a partir de Excel 2010 y lamentablemente no existe equivalencia para versiones anteriores. Solo la función MODA es equivalente a la función MODA.UNO.

Encontrar el valor más frecuente en texto

Una desventaja de las funciones mencionadas anteriormente es que solamente nos permiten trabajar con valores numéricos, pero en más de una ocasión nos veremos en la necesidad de encontrar el valor más frecuente en Excel pero utilizando valores de texto. Para resolver este problema debemos recurrir en primer lugar a la función COINCIDIR la cual hace la comparación de un valor con una matriz y nos devuelve la posición donde se ha encontrado dicho valor. En la siguiente fórmula hago un uso “especial” de esta función:

=COINCIDIR(A1:A10, A1:A10, 0)

Usualmente el primer argumento de la función COINCIDIR es el valor que estamos buscando, pero en esta fórmula estoy indicando un rango de celdas. Lo que obtendremos como resultado será una matriz con una serie de valores que nos indicarán la posición en la que encuentra cada uno de los valores del rango A1:A10. Para entender mejor esta fórmula, seleccionaré el rango de celdas C1:C10, copiaré la fórmula a la barra de fórmulas y pulsaré la combinación de teclas Ctrl + Mayús + Entrar.

Buscar el valor más frecuente en una lista de textos

Al utilizar de esta manera la función COINCIDIR obtenemos un arreglo de valores numéricos como el siguiente: {1,2,2,4,4,1,4,1,4,2}. Este arreglo de números es justamente lo que necesitamos para preguntar a la función MODA.UNO el valor que más se repite. De esta manera podemos armar la siguiente fórmula:

=MODA.UNO(COINCIDIR(A1:A10, A1:A10, 0))

En este caso ya no es necesario introducir la fórmula como si fuera matricial ya que la función MODA.UNO se encarga de decirnos el valor más frecuente entre los resultados de la función COINCIDIR. Observa el resultado de esta fórmula:

Función MODA con valores no numéricos

Con esta fórmula sabemos que el valor que más se repite es la posición 4 y que corresponde a Hugo. Para obtener dicho valor debemos complementar nuestra fórmula utilizando la función INDICE de la siguiente manera:

=INDICE(A1:A10, MODA.UNO(COINCIDIR(A1:A10, A1:A10, 0)))

Recuerda que si tienes Excel 2007, o una versión anterior, deberás utilizar la función MODA en lugar de MODA.UNO. Al ingresar esta fórmula obtendremos el texto más frecuente dentro del rango especificado:

Cómo obtener los valores más repetidos en Excel

De esta manera hemos encontrado el valor más frecuente en Excel sin importar si los valores son numéricos o de texto. Descarga el libro de trabajo y utiliza las fórmulas propuestas en este artículo para encontrar los valores que más se repiten en tus datos.

Moisés Ortiz

Autor: Moisés Ortiz

Moisés es consultor en tecnologías de la información con especialidad en herramientas de inteligencia de negocios y análisis de datos. Tiene más de 25 años de experiencia en el uso de Excel y es una de sus herramientas predilectas para la creación de reportes. Ver más ➤