La función CONTAR.SI.CONJUNTO en Excel

La función CONTAR.SI.CONJUNTO en Excel nos permite contar los elementos de un rango que cumplen con los criterios definidos. Esta función nos permite especificar hasta 127 criterios.

Sintaxis de la función CONTAR.SI.CONJUNTO

La función CONTAR.SI.CONJUNTO tiene dos argumentos obligatorios y los demás opcionales.

La función CONTAR.SI.CONJUNTO en Excel

  • Rango_criterios1 (obligatorio): El rango de celdas que será evaluado con el Criterio1.
  • Criterio1 (obligatorio): El criterio con que se evaluará el Rango_criterios1.
  • Rango_criterios2 (opcional): El rango de celdas que será evaluado con el Criterio2.
  • Criterio2 (opcional): El criterio que evaluará el Rango_criterios2.

A partir del Rango_criterios2, todos los argumentos son opcionales y se permiten hasta 127 rangos y criterios  a evaluar por la función CONTAR.SI.CONJUNTO. Cada rango especificado debe tener la misma cantidad de filas (o columnas) que los anteriores.

Ejemplo de la función CONTAR.SI.CONJUNTO

Para ejemplificar el uso de la función CONTAR.SI.CONJUNTO haremos un ejemplo muy sencillo. Tengo una lista de personas (hombres y mujeres) que están en un rango de edad entre los 15 y los 25 años de edad.

La primera cuenta que necesito hacer es la de conocer el número total de hombres y haré dicha cuenta con la función CONTAR.SI.CONJUNTO de la siguiente manera:

=CONTAR.SI.CONJUNTO(B2:B16, "Hombre")

El resultado de esta fórmula lo puedes observar en la celda F1 de la siguiente imagen:

Ejemplo de la función CONTAR.SI.CONJUNTO en Excel

Contar valores con más de una condición

El verdadero potencial de la función CONTAR.SI.CONJUNTO es cuando necesitamos especificar más de un criterio en nuestra cuenta. Por ejemplo, si en la lista anterior necesito contar los hombres mayores de 18 años puedo utilizar la siguiente fórmula:

=CONTAR.SI.CONJUNTO(B2:B16, "Hombre", C2:C16, ">18")

El resultado se muestra en la celda F2 de la siguiente imagen:

Contar con múltiples criterios en Excel

Cuando necesites contar elementos en Excel utilizando múltiples criterios, la función CONTAR.SI.CONJUNTO será de mucha utilidad.

130 pensamientos en “La función CONTAR.SI.CONJUNTO en Excel

  1. Jorge

    Èsta formula estaría perfecta, pero no quiero contar celdas ocultas que debería poner como criterio
    =CONTAR.SI.CONJUNTO(A1:A20,”JORGE”,A1:A20,”VISIBLES”) ????

    QUE CRITERIO DEBO DE PONER PARA QUE NO ME CUENTE LAS CELDAS OCULTAS??

    Responder
    1. Moisés Ortíz Autor

      Hola Jorge, no existe una manera de crear una condición que signifique “visibles”. Una buena alternativa es utilizar la función AGREGAR (en Excel 2010) la cual permite indicar a la función CONTAR que no tome en cuenta las celdas ocultas. Más información sobre la función AGREGAR en el siguiente artículo:
      http://exceltotal.com/la-funcion-agregar-en-excel/

      Responder
  2. Marco Antonio

    Buenas tardes. saben si en la formula sumar.si.conjunto hay manera de que tome en cuenta dos criterios en la misma columna?
    por ejemplo:
    Sumar.si.conjunto(A2:A129,B2:129,1,B2:B129,77)

    hasta ahora mi resultado es cero, y cuando le quito la condicion de 77 si me hace la suma obviamente sin tomar en cuenta este criterio 77.
    ojala me puedan ayudar con este problema. De antemano gracias por su atencion y apoyo
    Saludos.

    Responder
    1. Moisés Ortíz Autor

      Hola Marco Antonio, La fórmula está bien escrita pero el resultado es cero porque ambas condiciones nunca se cumplirán. Un número no puede ser igual a 1 y al mismo tiempo ser igual a 77. Pareciera que deseas sumar los valores de la columna A que tienen un 1 en la columna B y además sumar aquellos que tienen 77 en la columna B. Para ello deberás utilizar una fórmula como la siguiente:
      =SUMAR.SI.CONJUNTO(A1:A5, B1:B5, 1) + SUMAR.SI.CONJUNTO(A1:A5, B1:B5, 77)

      Responder
      1. Fredy

        excelente información, era tan simple y a la vez nunca se me ocurria como relacionar mas de una peticion, solo buscaba la opcion , =o , =or
        gracias gracias…

        Responder
      2. Josué

        Saludos… excelente aclaración Moisés, vieras que me ayudó mucho para resolver una tarea pero en función de “contar.si” cuando necesito integrar a una sola columna dos condiciones. Gracias.

        Responder
  3. Marco Antonio

    Buenos días Moisés
    Gracias por la solución, ya probé la formula como me la planteas y me funciona perfectamente.
    Nuevamente muchas gracias por la solución y una disculpa si tarde mucho en responder, no pensé que fueran tan rápidos.
    Saludos.

    Responder
  4. Ignacio

    Pues yo no he podido hacer funcionar la fórmula en una hoja de cálculo de EXCEL 2010.
    Mes a mes hacemos estadísticas de resultados de exámenes y se contabilizan los presentados y los aprobados.
    Para hacer más automática la contabilización de los mismos he colocado una hoja con los resultados de los exámenes y otra hoja con la tabla de datos a ser llenada.

    Por ejemplo, para contar los exámenes tengo una fórmula
    =CONTAR.SI.CONJUNTO(‘HOJA1′!$F$2:$F$100, “NOMBREMATERIA”)

    La cual funciona perfectamente para contabilizar las materias, pero dado que, también, debo contar aquellas que están aprobadas, estoy usando la fórmula siguiente
    =CONTAR.SI.CONJUNTO(‘HOJA1′!$F$2:$F$100, “NOMBREMATERIA”, ‘HOJA1′!$H$2:$H$100, “>5″)

    Sin embargo sólo obtengo ceros, con la idea de que al poner “>5″ sólo me contase las calificaciones mayores a 5.
    En el caso de colocar un valor concreto, en el segundo criterio de la segunda fórmula, quitando el operador > y sólo dejando el 5, obtengo el número correcto de reprobados de dicha materia.
    ¿Qué puedo hacer al respecto ya que no me funciona el operador >?
    ¿Qué podría estar mal en mi fórmula?
    Gracias de antemano por la orientación.

    Responder
    1. Moisés Ortíz Autor

      Hola Ignacio, Tu fórmula parece estar bien escrita, pero es probable que los valores de la columna H de la Hoja1 tengan formato de texto y por eso solo te funciona cuando los comparas con 5. Asegúrate que las celdas que tienen las calificaciones tengan formato de número de manera que puedas utilizar la comparación “mayor que”.

      Responder
  5. Daniel

    Hola, buenas noches, tengo una tabla con datos de hombres y mujeres de entre 18 y 40 años, necesito saber cuántos hombres hay de entre 18 y 22 años, ordené los datos por conjuntos: edad, sexo; solo puedo obtener valores de hombres mayores o menores de cierta edad, pero no entre dos edades. habra alguna funcion que pueda usar?

    Responder
    1. Moisés Ortíz Autor

      Hola Daniel, la función CONTAR.SI.CONJUNTO te puede ayudar solo debes repetir el mismo rango de criterio pero con diferente condición, por ejemplo:
      =CONTAR.SI.CONJUNTO(A1:A25, “>=18″, A1:A25, “< =22")

      Otra manera de hacerlo es utilizando la función SI junto con la función Y. Te dejo un artículo con más detalle:
      http://exceltotal.com/expresiones-logicas-en-excel/

  6. Fernando Pérez

    Hola, buenas tardes, segui tu recomendación, modique de la siguiente manera la formula:
    CONTAR.SI.CONJUNTO(AN5:AN20,>=AS15,AN5:AN20,< =AU15)
    AS15=0, AU15=10; la idea es contar los números que hay entre el 0 y el 10 y después (en otras celdas) del 10.1 al 30 y así sucesivamente. No he podido, podrías ayudarme?.
    Muchas gracias.
    Saludos.

    Responder
    1. Moisés Ortíz Autor

      Hola Fernando, ya que el valor del criterio está en una celda debes concatenarlo con los símbolos mayor/menor que:
      CONTAR.SI.CONJUNTO(AN5:AN20, “>=”&AS15, AN5:AN20, “<=”&AU15)

      Responder
      1. SERGIO

        muchas gracias, a pesar de no haber preguntado directamente me ha ayudado un monton este tip!

        Responder
      2. Juan Luis

        Muchas gracias. Me estaba volviendo loco de tanto intentar distintas soluciones.Esta definitivamente funciona!

        Responder
  7. Jaime

    Hola Moisés, creo que ya has respondido un caso parecido pero sigo dándole vueltas por si fuera posible usar la función CONTAR.SI.CONJUNTO para calcular el número de celdas de una columna que cumplan dos condiciones. Por ejemplo, si en la columna A tuviera los siguientes valores: 1,2,3,4,5,5,6,7. ¿Sería posible con esta función contar las veces que aparecen el 5 ó el 7?. Existe alguna alternativa para no escribir CONTAR.SI.CONJUNTO(A1:A8 ;5) + CONTAR.SI.CONJUNTO(A1:A8 ;7)? Muchas gracias

    Responder
    1. Moisés Ortíz Autor

      Hola Jaime, no existe alternativa, la solución es la fórmula que has escrito.

      Responder
  8. jhon

    muchas gracias por el aporte me ayudado bastante con mi trabajo gracias .

    Responder
  9. CESAR

    Saludos, quisiera utilizar la formula contar.si conjunto, para que me sume unas celdas en una misma columna que contengan el mismo texto, xej cesar , pero que las sume si en otra columna aparece el texto activo. si aparece cancelado que no lo sume. se puede utilizar? o cual me recomiendas que use, gracias

    Responder
    1. Moisés Ortíz Autor

      Cesar, me parece que estás buscando una fórmula como la siguiente:
      =CONTAR.SI.CONJUNTO(A1:A10, “Cesar”, B1:B10, “Activo”)

      Solo cambia el rango A1:A10 por el rango donde tienes los nombres y B1:B10 donde se encuentran los valores Activo/Cancelado.

      Responder
      1. Alberto Lucero

        Buenas,

        estimado, como aplico esta formula en Inlgés ?

        Responder
        1. Moisés Ortíz Autor

          Hola Alberto, el equivalente de la funcion CONTAR.SI.CONJUNTO en inglés es COUNTIFS.

          Responder
  10. Romel Reategui

    Hola Moises, habria la forma de aplicar la formula de contar.si.conjunto que me sirva com contador de datos, como referencia tome las celdas con datos.

    Responder
  11. José

    Buenas tardes.
    Tengo una hoja excel con trabajos que realizamos en 9 rutas..
    En una columna estan todas las ventas (En Euros) y en otra la ruta (De la A a la I) a la que corresponde.
    Que formula puedo emplear para que en una celda me sume la suma de las ventas por ruta, es decir al lado de la A me apareceria el valor total de las ventas en esa ruta y sucecivamente hasta la I.
    Saludos y muchas gracias.

    Responder
  12. Rosario

    Hola Moisés, tengo un libro con 07 hojas y en la ultima tengo que hacer un resumen de los datos que tengo en las otras seis hojas, ejemplo; necesito poner en una celda la cantidad total de camisas manga corta talla 34, en otra celda la cantidad total de talla 36 y asi sucesivamente, informacion que la tengo concentrada en diferentes hojas, por lo que mi pregunta es ¿puedo utilizar la formula SUMAR.SI.CONJUNTO con datos de disitintas hojas? o en dado caso ¿cual seria la formula correcta?

    De antemano, agradezco infinitamente tu apoyo.

    Responder
    1. Moisés Ortíz Autor

      Hola Rosario, la tabla con los datos puede estar en cualquier hoja, pero no puedes mezclar datos de diferentes hojas en una misma función. Deberás utilizar una función CONTAR.SI.CONJUNTO para cada hoja. Por ejemplo, la siguiente fórmula cuenta las coincidencias de la Hoja1 y lo suma a la cuenta de la Hoja2:
      =CONTAR.SI.CONJUNTO(Hoja1!A1:A100,34) + CONTAR.SI.CONJUNTO(Hoja2!A1:A100,34)

      Responder
  13. LUIS ROJAS

    muchas gracias hermano, me ha sido super útil este tutorial.

    Responder
  14. Jorge

    Hola Moises.
    Existe alguna forma de que la fórmula, descrita en tu primer ejemplo (=CONTAR.SI.CONJUNTO((B2:B16, “Hombre”)) pueda extenderse a un rango variable, es decir, que el rango B2:B16 sea de B2:hastaceldadondenohayamasdatos.
    Tengo una planilla donde, por ejemplo, necesito contar pero el dia lunes tengo 9897 datos, el martes son 10293, el miércoles 8645, y así sucesivamente todos los días cambia. Entonces necesito que la fórmula cuente automáticamente para rangos diferentes.
    Desde ya muchas gracias por tu ayuda.
    Saludos!

    Responder
    1. Moisés Ortíz Autor

      Hola Jorge, hay dos posibles soluciones a tu problema:
      1) Si el rango B2:B16 formara parte de una tabla, entonces es posible indicar la columna directamente en la función CONTAR.SI.CONJUNTO de la siguiente manera:
      =CONTAR.SI.CONJUNTO(Tabla1[Sexo],”Hombre”)
      En mi ejemplo los datos no están como tabla de Excel, pero si conviertiera el rango en tabla, entonces la fórmula anterior se actualizaría automáticamente al agregar una nueva fila.

      2) Si no es posible crear una tabla, entonces puede utilizar un rango dinámico. Consulta el siguiente artículo:
      http://exceltotal.com/nombres-de-rango-dinamicos/
      En este artículo verás que uso la función SUMA, pero se puede implementar la misma solución con la función CONTAR.SI.CONJUNTO.

      Responder
  15. CESAR

    Hola Moises,
    e intentado bastante utilizar esta formula pero no estoy encontrando mi error
    =contar.si(AD45:AD69;”CESAR”)
    quisiera contar cuantos trabajos fue asignado a este nombre asi como a los demas nombres que estan en esa columna
    al darle enter me aparece el siguiente error: #NAME?

    Responder
    1. Moisés Ortíz Autor

      Hola Cesar, Por el tipo de error que mencionas (#NAME) debes tener Excel en inglés y el error se debe a que Excel no reconoce el nombre de la función en español. Debes utilizar las funciones por su nombre en inglés. La función CONTAR.SI en inglés es COUNTIF.

      Responder
  16. damian

    hola, queria saber si hay manera que la funcion sumar.si.conjunto tome datos de una tabla traida de una base de datos a excel. osea no creo que sea error de la formula por que si hago una tabla exactamente igual pero con valores escritos a mano la formula funciona pero si los datos los tomo de la tabla traida de axces a una hoja de excel siempre me da “0″
    la verdad no se que mas probar
    saludos!

    Responder
    1. Moisés Ortíz Autor

      Hola Damián, En realidad a la función CONTAR.SI.CONJUNTO no le importa la procedencia de los datos. Estoy seguro de que tu problema es el formato de los datos después de haberlos importado. Debes asegurarte de que los valores de texto efectivamente se importan como texto así como los valores numéricos de lo contrario podrás estar comparando valores numéricos con texto y por lo tanto no habrá ninguna coincidencia.

      Responder
  17. Jorge

    Estimado Moises, tengo una base de datos que e llamado a esta Hoja (MAIN) la cual tiene nombres, edad sexo semestre, status (activo, baja, suspendido etc) de ella e derivado otras ejemplo Poblacion activa en donde aparecen los datos de aquellos con status Activo en otra hoja quiero poner en una celda el total de 1° semestre con edad de 15 (años) y (sexo) Hombre he utilizado la siguiente formula que e desarrollado siguiendo las tutorías que te he visto publicar pero al darle enter me despliega una ventana que pregunta Actualizar Valores: Activa´ y me muestra muchos archivos para yo seleccionar y si selecciono uno luega me muestra otra ventana donde me pide seleccionar hoja y la que seleccione la adjunta en la formula pero de ninguna manera realiza la funcion deseada; Hojala seas tan amable en ayudarme. Gracias

    Responder
  18. Jorge

    Moises a continuacion muestro la formula que construí =CONTAR.SI.CONJUNTO(‘Poblacion Activa’!$C$11:$C$162, “1″, ‘Poblacion Activa’!$I$11:$I$162, “15″, ‘Poblacion Activa’!$J$11:$J$162, “Hombre”)

    Responder
    1. Moisés Ortíz Autor

      Jorge, el mensaje de Actualizar Valores se muestra cuando en tu libro existen referencias a otros libros que están cerrados por lo que no necesariamente tiene que ver con la fórmula que publicas. En la ficha Datos > Conexiones revisa que no tengas una conexión a un libro cerrado. También revisa que no hayas definido algún Nombre que haga referencia a un libro cerrado.

      Responder
  19. JAVIER

    quiero contar 4 criterios con contar.si.conjunto en un mismo rango y siempre me da cero hay alguna forma de ealizar esta formula =CONTAR.SI.CONJUNTO(B5:B12;B6;B5:B12;B8;B5:B13;B12)

    Responder
    1. Moisés Ortíz Autor

      Hola Javier, recuerda que la función CONTAR.SI.CONJUNTO buscará los valores que cumplan con TODOS los criterios así que es probable que no tengas celdas que cumplan. No puedo ayudarte mucho porque en tu fórmula no puedo ver los criterios que estás utilizando.

      Responder
  20. Lennin

    Moises,, Buenas,, observando que eres el teso en excel, me hicieron una inquietud la cual te hago acá:
    Existe alguna formula , función o tocara hacer una macro en VBA para que el excel me diga cuales son las celdas que contienen los numeros que me den como resultado un valor que se escriba?
    Ejemplo: tengo una fila con varios valores.
    A B C D F
    5 , 8, 6 , 9 , 7

    Yo quiero decirle 23, y el excel me marque las columnas B,C Y D que corresponde a esa suma.
    se podra??

    Responder
    1. Moisés Ortíz Autor

      Hola Lennin, definitivamente tiene que ser una macro.

      Responder
  21. Mauricio

    Hola Moises,
    Que formula debo de utilizar en donde el resultado cumpla con dos condiciones o más, por ejemplo, que me traiga el valor de la celda E8, siempre y cuando D8 sea 320 y F8 477.

    Gracias por tu respuesta.

    Responder
  22. Rita

    Buenas tardes, quisiera saber si existe en excel una función que me permita contar valores, pero por unica vez, o sea, no contar las repeticiones de cada uno, es posible? Algún truquito?

    Gracias

    Responder
  23. Almudena

    Hola Moisés,

    en mi caso tengo una columna con diversos valores (9, 10, 11, 12… etc.) que se van repitiendo. Si quisiera que me contara cuántas veces aparece el valor 9, cuántas veces aparece el 10…etc.. SIN SUMARLO de forma que me apareciera un número por cada valor (es decir, 9 aparece 10 veces, el 10 aparece 5 veces…) existe una fórmula para hacerlo con una sola únicamente?

    Muchíííísimas gracias!!
    Almudena

    Responder
    1. Moisés Ortíz Autor

      Hola Almudena, no es necesario que utilices CONTAR.SI.CONJUNTO, puedes utilizar la función CONTAR.SI pero no puedes hacer todas las operaciones en una misma fórmula sino que debes utilizar una fórmula diferente para contar cada valor. Por ejemplo, para contar el número de veces que aparece el numero 10 debes utilizar la siguiente fórmula:
      =CONTAR.SI(A1:A10,10)

      Responder
  24. JAVIER

    SE PUEDE HACE UN “CONTAR SI CONJUNTO” CON UNA CONDICION U OTRA.
    ES DECIR NO CON DOS CONDICIONES > EDAD Y > ALTURA, SINO QUE SEA >EDAD O >ALTURA, QUE COJA
    CUANDO SE CUMPLA UNO U OTRO VALOR. NO UNO Y OTRO.

    SINO SE PUEDE ¿HAY OTRA FORMA DE HACERLO?, YA QUE PRETENDO QUE NO SE REPITAN LOS VALORES..
    SI HAGO POR SEPARADO UNA Y OTRA HABRÁ VALORES DUPLICADOS.

    SALUDOS

    Responder
    1. Moisés Ortíz Autor

      Hola Javier, puedes utilizar la función SI junto con la función O para obtener las celdas que cumplen alguna de las dos condiciones y posteriormente contarlas.

      Responder
  25. Cristian

    Tengo que contabilizar la cantidad de celdas que contienen notas superiores a 4 y menores de 5 teniendo Excel 2003 utilizando la formula contar.si.conjunto pero no encuentro la formula. ¿será que esta no existe para esta versión de Excel?. Agradecería vuestra ayuda.

    Responder
    1. Moisés Ortíz Autor

      Hola Cristian, la función CONTAR.SI.CONJUNTO está disponible a partir de Excel 2007.

      Responder
  26. Carlos

    Hola Moisés; Tengo un problema con la formula contar.si.conjunto, y es que la he utilizado para detectar duplicados en un listado de facturas recibidas, con dos restricciones, el número de factura y el nombre del proveedor (si cuenta más de dos aparece el mensaje “duplicados”. El tema es que cuando el número de la factura tiene muchos dígitos parece que solo mira x dígitos a la izquierda porque me dicen que son iguales p.ej. 2013000000000099 y 2013000000000098.
    Saludos y Gracias

    Responder
    1. Moisés Ortíz Autor

      Hola Carlos, Excel soporta una precisión máxima de 15 dígitos y el número que mencionas tiene 16 dígitos por lo que no detectará la diferencia entre ambos.

      Responder
  27. Yandru Castillo

    Buenos días Moisés quisiera saber como podría formular un conteo de fechas similares de dos columnas diferentes según el mes.

    estoy formulando de la siguiente forma y mas abajo explico que necesito, mil gracias!
    =CONTAR.SI.CONJUNTO(‘TIERRA COLINA’!N13:N348;”>=01/01/2013″;’TIERRA COLINA’!P13:P348;”<=31/01/2013")
    el resultado que me calcula es 2.

    pero necesito que no me repita la fecha por que la coincidencia seria 1 como resultado de este ejemplo:

    columna N columna P
    1-1-13 1-1-13
    2-1-13 1-1-13

    Gracias!!!!!

    Responder
    1. Moisés Ortíz Autor

      Hola Yandru, eso no es posible de hacer con la función CONTAR.SI.CONJUNTO ya que no está hecha para hacer conteos de valores únicos sino para contar todos los valores que cumplan las condiciones establecidas. La alternativa de solución es crear una macro para llevar el registro de las fechas previamente contadas.

      Responder
  28. José

    Estimado, consulta quiero usar la formula contar.si para que me cuente las celdas con un formato determinado, por ejemplo las celdas rellenadas con amarillo… es posible hacerlo?

    Responder
  29. Omar

    Estimado Moises estoy haciendo un conteo las condiciones son contar si en el rango la fecha y la hora coinciden, ya alguna vez lo hice pero ahora no me sale la formula la estoy escribiendo asi =CONTAR.SI.CONJUNTO(N3:N1832,=$N$1835;R3:R1832=$R1836) donde el rango de N3:N1832 se encuentra la fecha y$N$1835 es la columna y linea donde está la fecha especifica R3:R1832 se encuentra la hora que lo convertí a número es decir 07:00 lo converti a 7 y $R$1836 tengo la hora especifica que quiero que me cuente.

    Saludos.

    Responder
    1. Moisés Ortíz Autor

      Hola Omar, los criterios no pueden ser referencias directas a celdas sino texto o números y por o tanto debes concatenar el valor de la celda que contiene la fecha. Por ejemplo:
      =CONTAR.SI.CONJUNTO(N3:N1832,”=” & N1835)

      Observa la manera en que construyo el segundo argumento con el valor de la celda N1835.

      Responder
  30. César

    Hola Moises, tengo una problema a ver si me puedes ayudar. Tengo una hoja en que el rango criterio a contar no es consecutivo sino hay saltos… se puede solucionar de alguna manera? Hay una manera que es copiar esos datos y hacer el rango consecutivo.. pero quería saber si exsite una forma más “limpia”. Por otro lado esa misma formula como criterio 1, tiene que coger un dato que es variable y lo recoge de otra celda y me sale entonces “>b34″.. y no me cuenta las celdas, que solución encuentras? Gracias de antemano.

    Responder
    1. Moisés Ortíz Autor

      Hola César, en cuanto al rango de criterios, es forzoso que sea consecutivo para la función CONTAR.SI.CONJUNTO de lo contrario tendrías que utilizar otras funciones como INDIRECTO y SUMAPRODUCTO. En cuanto al criterio “>b34″ supongo que el problema es porque la cadena comienza con el símbolo > y por lo tanto la función intenta contar los valores mayores a “b34″. Creo que tu caso es de aquellos que conviene resolver con funciones diferentes, te dejo un ejemplo de otra alternativa para contar en Excel:
      http://exceltotal.com/sumar-y-contar-con-varias-condiciones-en-excel/

      Responder
  31. Alejandro

    Buenas tardes Moisés:
    Estoy con una hoja de cálculo, en la cual la primera columna, es el día del mes, seguido de la letra de la semana.
    y las columnas laterales tienen un nombre.
    Es para hacer el calculo en cuadrante de trabajo.
    Por ejemplo, A9 correponde a 1S (sabado dia 1), a la derecha, desde B9 hasta m9, serían nombres.
    Pues bien lo que me cuente el numero de veces que aparece un determinado nombre en los distintos sabados.
    eN 2007, sería algo así CONTAR.SI.CONJUNTO(A9:A38, “S”, B9:M38, “Alejandro”), para que me contase los dias que trabajo en sabado.
    Pero tengo el 2.003. Así que si me pudieses indicar como hacerlo sería estupendo.
    Gracias de antemano.

    Responder
  32. LINO

    Buenos días Moises, me gustaría que me orientes para una formula de una hoja de calculo en excel en donde vaciamos quincena por quincena la asistencia de base para la nómina de donde al final de los horarios me de un resúmen de faltas, vacaciones, permisos, incapacidades y los mas importantes -con tu apoyo- resúmenes de retardos en donde la tolerancia es a partir de 8:30 a las 8:45 y de las horas extras en donde la hora de salida es a las 17:00, utilicé la función =CONTAR.SI(E8:AJ8,”>=8:31<=8:45") pero no me dá bien el resultado. Te comento que de cada día se captura en una celda la entrada y en otra la salida, solicito tu ayuda por favor, de antemano muchas gracias.

    Responder
    1. Moisés Ortíz Autor

      Hola Lino, en realidad necesitas dos criterios y no solo uno, es decir, necesitas contar las horas mayores a 8:30 (criterio 1) y que además sean menores a 8:45 (criterio 2).
      Así que, la función CONTAR.SI no es útil para esto porque solo permite un criterio. Es necesario que utilices la función CONTAR.SI.CONJUNTO de la siguiente manera:
      =CONTAR.SI.CONJUNTO((E8:AJ8,”>=8:31″,E8:AJ8,”<=8:45″)

      Responder
  33. lalillo

    hola, eh leído muchos comentarios y me anime a publicar mi duda que es la siguiente:
    cada semana lleno una base de datos dando un valor binario (1 o 0) a diferentes categorías dependiendo si cumplen o no con un criterio y al final de la semana alimento una hoja con los ceros, actualmente uso la formula en cuestión para que le arroje los ceros sin embargo tengo que estar cambiando manualmente el rango de las celdas a calcular porque el numero de registros por semana es variable, lo que necesito es evitar cambiar este rango manual y determinarlo por una categoría en este “platino”, espero me haya explicado y ojala se pueda realizar lo que expongo!!, un saludo y buen fin de semana!!!

    Responder
  34. marcelo

    Tengo una fila con números telefónicos y quieron contar cuantos veces un numero se repite, por ejemplo
    543874129503
    543844475125
    154129503
    como veras están ingresados de distintas formas, yo necesito contar los que terminan en 4129503, en este ejemplo serian 2 pero como lo hago con una funcion

    Responder
    1. Moisés Ortíz Autor

      Hola Marcelo, utiliza el criterio “*4129503″ para contar todos los números que terminan en 4129503.

      Responder
  35. SANDRA

    HOLA MOISES COMO PUEDO UTILIZAR EL CONTAR.SI.CONJUNTO EJEMPLO:NECESITO NOTAS >15 PERO Q NO SEAN DE LA ESPECIALIDAD DE MEDICINA
    =CONTAR.SI.CONJUNTO(G5:G29,”>15″,D5:D29,????? NO C COMO EXCLUIR ESA FACULTAD

    Responder
    1. Moisés Ortíz Autor

      Hola Sandra, utiliza la siguiente fórmula:
      =CONTAR.SI.CONJUNTO(G5:G29,”>15″,D5:D29,”<>MEDICINA”)

      Responder
  36. francisco

    hola, como copiar esta formula en filas hacia abajo pero que me respete el mis rango de datos. (el criterio y rango estan en diferentes hojas) saludos.

    Responder
  37. Fabricio

    Hola, necesito contar celdas de una fila que sean mayor a 0, y que en la fila siguiente cumplan con la condición de ser números pares, como puedo aplicar contar si, y la función es par ?

    Responder
    1. Moisés Ortíz Autor

      Hola Fabricio, no es posible aplicar esa lógica al criterio de la función CONTAR.SI.CONJUNTO. Te recomiendo agregar una columna auxiliar donde utilices la función ES.PAR y posteriormente en la función CONTAR.SI.CONJUNTO evaluar si dicha columna auxiliar es verdadera.

      Responder
  38. ERASMO LICONA CERON

    NECESITO HACER UNA COMBINACION DE ESTA FUNCION =CONTAR.SI.CONJUNTO(C6:C61,”SI”) QUE ME SIRVE PARA ENCONTRAR CUANTAS VECES SE ENCUENTRA LA PALABRA SI EN UNA COLUMNA PERO NECESITO HACER QUE ME DETENGA CUANDO YA ALLA MAS DE 6 VECES SI

    Responder
    1. Moisés Ortíz Autor

      Hola Erasmo, no es posible “detener” la cuenta que realiza la función. Lo que puedes hacer es utilizar la función SI para indicar alguna acción especial en caso de que el resultado sea mayor a 6, por ejemplo:
      =SI(CONTAR.SI.CONJUNTO(C6:C61,”SI”) >= 6, “MAYOR A 6″, “MENOR A 6″)

      Responder
  39. David V.

    Q tal compañero, cuando colo la formula =CONTAR.SI.CONJUNTO(A:A, “Cerrado”) ya que quiero que cuente cada vez q figure la palabra cerrado de toda la columna, pero me vota el error #¿NOMBRE?.

    Q PUEDE OCASIONAR EL ERROR… te comento igual que la palabra se cerrado la arroja una macro en visual al excel al colocar un botón actualizar y ya coloque todo en formato de celda numero.

    Responder
    1. Moisés Ortíz Autor

      Hola David, el error #¿NOMBRE? solo se muestra cuando Excel no reconoce la función indicada. Sospecho que tienes Excel 2003 …
      Recuerda que la función CONTAR.SI.CONJUNTO apareció por primera vez en Excel 2007.

      Responder
  40. edgar

    Moises excelente trabajo y muchas gracias por tu ayuda me ha servido mucho tus explicaciones. te felicito y te deseo muchas bendiciones.

    Responder
  41. Alejandro

    Buenas tardes Moises, quisiera saber si me puedes ayudar en lo Siguiente:

    Tengo una Base de datos, en donde se agrupan varios Valores iguales. quisiera saber si hay alguna función que cuente solo los valores que no son iguales, es decir, que si tengo el mismo valor 10 veces lo tome como 1.

    Gracias de antemano…

    Responder
      1. Alejandro

        Gracias Moisés, Problema resuelto!
        Saludos..!

        Responder
  42. Israel

    Hola moises si me puedes ayuda por favor. Como le hago si quiero que cuente dado un criterio1 o un criterio2, digamos tengo una columna llamada “prioridad” quiero que cuente las filas que sean “criticas” o “altas”
    F13:F225,criticas, F13:F225,altas Si lo pongo de esta forma ninguna cumple y no me las cuenta
    alguna función que me pueda ayudar?
    Gracias por tu ayuda

    Responder
    1. Moisés Ortíz Autor

      Hola Israel, eso sucede porque no hay celda que cumpla las dos cosas al mismo tiempo, es decir, que sea “crítica” y “alta” al mismo tiempo. Debes hacer las cuentas por separado, por ejemplo:
      =CONTAR.SI.CONJUNTO(F13:F225, “criticas”) + CONTAR.SI.CONJUNTO(F13:F225, “altas”)

      Ya que solo estarías indicando un solo criterio para cada función CONTAR.SI.CONJUNTO, entonces podrías utilizar también la función CONTAR.SI.

      Responder
  43. Alfonso Aguirre

    Hola. Estoy utilizando la función “sumar.si” y en ella quiero sumar los valores de una columna tomando como criterio los valores que sean >= a el valor que escriba en otra celda p.e. j5. en donde j5 es = a 8.
    la formula me da la respuesta correcta si escribo =SUMAR.SI(A5:A48,”<8",F5:F48). pero si pongo =SUMAR.SI(A5:A48,"<j5",F5:F48), no me responde ningún valor. ¿Qué puedo hacer? Gracias

    Responder
    1. Moisés Ortíz Autor

      Hola Alfonso, la manera correcta de incluir el valor de una celda en el criterio es la siguiente:
      =SUMAR.SI(A5:A48,”<” & J5,F5:F48)

      Responder
  44. ANGEL GREGORIO ROJO

    DESPUES DE LEER DOS VECES LA TEORIA Y REALIZAR LOS EJERCICIOS AQUI EXPUESTOS COMENZARE AHORA CON MAS CONFIANZA A CREAR MIS PROPIAS TABLAS PARA APLICARLAS A MI ACTIVIDAD DIARIA. LA FUNCION CONTAR.SI.CONJUNTO ME SIMPLIFICARA MIS TAREAS DIARIAS. DESDE YA GRACIAS A UD.

    Responder
  45. sebastian saavedra

    hola, he leido esto ya varias veces, pero aun no se si la funcion contar.si.conjunto me sirve para contar datos dentro de un rango de fechas, por ejemplo la cantidad de personas que solicitan un servicion entre el 01/01/2013 al 28/02/2013.

    de antemano muchas gracias

    Responder
    1. Moisés Ortíz Autor

      Hola Sebastian, suponinendo que las fechas se encuentran en el rango A1:A365, puedes utilizar la siguiente fórmula:
      =CONTAR.SI.CONJUNTO(A1:A365,”>01/01/2013″, A1:A365, “<28/02/2013″)

      Responder
  46. Israel

    Buenas tardes, cuento con excel 2003 y necesito contar algo similar como el ejemplo del principio de ésta función, pero no encuentro ésta función, leyendo los comentarios me he dado cuenta que dice que en el 2003 no existe ésta función, entonces como puedo hacer para poder evaluar dos condiciones y poder contar como lo hace ésta función, básicamente lo que quiero es como en el ejemplo, contar cuantas personas son de sexo masculino y además cuántas de ellas tienen fecha de ingreso igual, agradeceré mucho su ayuda, saludos

    Responder
  47. rodrigo

    Hola, como puedo contar dos variables en una misma colunma, no me reusulta y me cuenta cero. para que me funcione debo repetir la función, quisiera saber si hay otra forma de hacerlo
    =+CONTAR.SI.CONJUNTO(B4:B42;”LOCALES MENORES”;G4:G42;”F”)+CONTAR.SI.CONJUNTO(B4:B42;”LOCALES MENORES”;G4:G42;”c”)
    B–< SON LOCALES
    G–< M2
    F Y C–< ESTADO

    Quiero contar cuantas F y C hay con esa regla.

    Responder
    1. Moisés Ortíz Autor

      Hola Rodrigo, la única solución es la que ya estás utilizando.
      Cuando colocas las dos condiciones en la misma función te devuelve cero porque un mismo valor no puede ser “F” y “C” al mismo tiempo.

      Responder
  48. Monica

    Buenas tardes:
    Quisiera saber cómo hago para que excel me cuente los criterios que estén seleccionados con un color determinado.
    Gracias.

    Responder
  49. Alberto Gonzalez

    Hola moises, necesito de tu ayuda. tengo un rango de fechas de 2013 y 2014. Solo quiero contar los eventos de 2014. Como podria hacerlo?

    Responder
    1. Moisés Ortíz Autor

      Hola Alberto, suponiendo que la columna A tiene las fechas puedes utilizar la función CONTAR.SI.CONJUNTO de la siguiente manera:
      =CONTAR.SI.CONJUNTO(A1:A99,”>=01/01/2014″,A1:A99,”<=31/12/2014″)

      Responder
  50. Antonio Romero

    Hola Moises, necesito to guia, estoy usando contar.si.conjunto y quisiera saber como hago para contar solo las celdas que tenga una letra especifica, por ejemplo en una celda tengo +++f y en otra tengo ++v, lo que quiero es contar todas las contengan f

    Responder
    1. Moisés Ortíz Autor

      Hola Antonio, utiliza el criterio “*f” y se contarán todas las celdas que terminen con la letra f. Por ejemplo:
      =CONTAR.SI.CONJUNTO(A1:A99,”*f”)

      Responder
  51. Beto

    Buen día, excelentes y uy útiles sus enseñanzas.
    Mi consulta esta referida a que al cargar la fórmula donde debo contar las celdas donde se repiten dos condiciones, me aparece #NAME?. EJ. Columnas de tipo de ventas y vendedores llamados Gonzalez. =contar.si.conjunto(‘año 2010′!AI5:AI1930;”Gonzalez”,Q5:Q1930,”Cuotas”)
    Puede haber un error de sintaxis? Gracias por sus respuestas

    Responder
    1. Moisés Ortíz Autor

      Hola Beto, el error #NAME me indica que tienes Excel en inglés y por lo tanto debes utilizar las funciones equivalentes en dicho idioma.
      En el caso de la función CONTAR.SI.CONJUNTO, su nombre en inglés es: COUNTIFS

      Responder
  52. Juan José

    Buenas tardes, Moisés.
    Quisiera saber cómo utilizar esta función para contar los datos de 7 en 7 dentro de un conjunto de datos. Intenté con la siguiente combinación para obtener lo buscado:
    =CONTAR.SI.CONJUNTO(C2:C510,(RESTO(FILA(C2:C510),7)=6))
    Aquí, trato de excluir los valores de las filas 1 a la 6 y tomar sólo la séptima, pero obtengo sólo cero. ¿Faltarán más condiciones?

    Responder
    1. Moisés Ortíz Autor

      Juan José, lo que estás haciendo con esta fórmula es contar aquellas celdas en el rango C2:C510 cuyo valor sea VERDADERO.
      Lo que te recomiendo es crear una columna auxiliar donde coloques la fórmula (que debe estar igualada a cero): =RESTO(FILA(B1), 7)=0
      Esta columna tendrá el valor VERDADERO para las filas que son múltiplos de 7 y entonces puedes utilizar la función CONTAR.SI.CONJUNTO para contar los valores VERDADERO.

      Responder
  53. JACY

    Buenos días quisiera saber si puedo utilizar contar.si .conjunto en el caso de que tenga 3 criterios en mi caso tengo que contar el trato a los pacientes de un hospital en base a su sexo y a su especialidad.

    Responder
    1. Moisés Ortíz Autor

      Hola Jacy, por supuesto que puedes utilizar la función CONTAR.SI.CONJUNTO con tres criterios, de hecho la función acepta hasta 127 criterios.

      Responder
  54. Sara

    Buenas tardes,
    Estoy intentando mediante la función promedio.si.conjunto (supongo que el funcionamiento será similar a la de contar), que el criterio sea variable y dependa del valor de una celda (para poder replicar la función en varias columnas con diferentes datos. La función sería algo asi:

    =PROMEDIO.SI.CONJUNTO(D3:D22;D86:D105;”<D81")

    El problema está en el último criterio, si lo pongo que sea igual a la celda D81 no hay problema, si lo pongo <de 10 (con un nñumero concreto) tampoco hay problema, pero no se como ponerlo menor que el valor de la celda ya que en el ejemplo "<D81" coge D81 como texto al tener que ir entre comillas pero no se como ponerlo como referencia.
    ¿Esto es posible?

    Muchas gracias

    Responder
    1. Moisés Ortíz Autor

      Hola Sara, debes indicar el criterio de la siguiente manera:
      =PROMEDIO.SI.CONJUNTO(D3:D22;D86:D105;”<“&D81)

      Responder
  55. Laura

    Hola, tengo un excel que contiene la relación de todas las personas que viven en cada vivienda de un área determinada, yo quiero una función que me permita contar la cantidad de familias en esa área, por ejemplo, en el excel pueden exsitir más de una persona con el mismo número de vivienda, eso sería una familia, cuando cambie el número de vivienda es que quiero que aumente el contador

    Responder
      1. Laura

        Muchísimas gracias eso era la que necesitaba. Funcionó perfectamente.

        Responder
  56. YURIANNY

    Hola Buenas Tardes,

    estoy aplicando esta formula

    =CONTAR.SI.CONJUNTO(C6:C29; “PERFORADOR”; E6:NF29; “FI”)

    para saber las faltas justificadas del perforador nada mas y me sale #¡VALOR!, que estare haciendo mal, o para esta formula solo se puede seleccionar un rango de una columna nada mas, y aqui estoy seleccionando un rango bastante grande que es E6:NF29; “FI”

    Responder
    1. Moisés Ortíz Autor

      Hola YURIANNY, los criterios de la función CONTAR.SI.CONJUNTO solamente se pueden aplicar por columnas, es decir, no es válido colocar E6:NF29. Solo se puede indicar las condiciones por columna que deseas evaluar, por ejemplo:
      =CONTAR.SI.CONJUNTO(C6:C29; “PERFORADOR”; E6:E29; “FI”; F6:F29; “FI”; G6:G29; “FI”)

      La fórmula anterior contará solamente las filas que tengan el valor “PERFORADOR” en la columna C y que además tengan el valor “FI” desde la columna E hasta la columna G. Si alguna de estas condiciones no se cumple, dicha fila no será incluida en la cuenta. Desconozco por completo tus datos, así que no sé si lo que quieres es contar las filas que tienen forzosamente el valor “FI” desde la columna E hasta la columna NF.

      Responder
  57. SANDY

    Buenas tardes. Quisiera tu colaboracion con la siguiente inquietud:
    Debo comparar las notas de tres periodos, y necesito contar los alumnos que en el segundo periodo (B) obtuvieron una nota superior al primero (A), y en el tercero (C)superior al segundo. Es decir A<B<C. Las notas de del periodo A estan en el rango D28:D37, las del periodo B en el rango I28:I37 y las del periodo C en el rango N28:N37…. no he podido con la formula seria:
    CONTAR.SI.CONJUNTO(D28:D37,"<="I28:I37", I28:I37,"<="N28:N37…. por su puesto esto me genera error…
    Agradezco tu ayuda.

    Responder
    1. Moisés Ortíz Autor

      Hola Sandy, no es posible indicar un rango dentro de un criterio (<=I28:I37) en la función CONTAR.SI.CONJUNTO así que te recomiendo hacer lo siguiente: Crea una columna auxiliar donde hagas la evaluación A

      Responder
  58. Arturo

    Hola, mi caso es distinto y no sé si vale esta fórmula para aplicar. En este caso necesito contar las apariciones de un nombre en una columna, pero en este caso puede haber más de un solo nombre en una celda y debería ser contado una vez por cada aparición de un nombre, es posible?

    Responder
  59. Florencia

    Hola buenas tardes. Tengo una planilla con una columna con número de cheques y otra con los importes de cada uno. Necesito sumar en una celda los importes de los cheques que tengan igual número de cheque. Es esto posible? Ya que el criterio es variable (mejor dicho una comparación entre números pertenecientes a un rango).
    Muchas gracias!!

    Responder
    1. Moisés Ortíz Autor

      Hola Florencia, para lograrlo es necesario extraer primero la lista de números de cheque “únicos”. Eso lo puedes lograr siguiendo alguno de los métodos mostrados en el siguiente artículo:
      http://exceltotal.com/extraer-valores-unicos-en-excel/

      Una vez que tengas la lista de números de cheque únicos podrás utilizar la función SUMAR.SI para sumar todos los importes correspondientes al mismo número de cheque.

      Responder
  60. marino

    Hola moises
    intento contar en una misma linea palabras diferentes, llego con una sola pero varias no.
    ejem, =CONTAR.SI.CONJUNTO(C22:AH22; “X”) y me cuenta el total de las X, pero en la misma linea hay letras o palabras diferentes y quiero que las cuente también.
    intento poner de esta forma i me deja la celula en blanco
    =CONTAR.SI.CONJUNTO(C22:AH22;”X”;C22:AH22; “T”)
    Gracias de antemano

    Responder
    1. Moisés Ortíz Autor

      Hola Mariano, la segunda fórmula que has colocado devuelve cero porque está contando las celdas que son igual a “X” e igual a “T” al mismo tiempo y eso jamás sucederá. La fórmula que te devolverá el resultado correcto es la siguiente:
      =CONTAR.SI.CONJUNTO(C22:AH22;”X”) + CONTAR.SI.CONJUNTO(C22:AH22; “T”)

      Ya que solo existe un criterio por función, puedes sustituirla por la función CONTAR.SI.

      Responder
  61. Karen

    Hola, Necesito una ayuda tengo una tabla con varias varibles, sucursal, almacen, codigo, costo. Necesito saber cuantos precios diferentes tiene los codigos de una sucursal especifica. Logro ver la cantidad de veces que tengo el codigo, (con un contar.si.conjuto)pero no se como identificar cuantos precios distinto tiene cada codigo.

    Espero me puedas ayudar.

    Responder
  62. Rodrigo Farias

    Hola Moises
    Tengo un problema, tengo una lista de edades y necesito agruparlas en distintas categorías.
    Por ejemplo de 25 a 35 años, de 35 a 45 años y quiero que lo haga automaticamente, que función me recomiendas, gracias de antemano.

    Responder
    1. Moisés Ortíz Autor

      Hola Rodrigo, si por agruparlas te refieres a contar cuántos registros tienes en el rango 25 a 35 años, entonces la función CONTAR.SI.CONJUNTO es la ideal, por ejemplo:
      =CONTAR.SI.CONJUNTO(A1:A99, “>25″, A1:A99, “<35″)

      Responder
  63. Abraham

    Hola, quisiera SUMAR dos factores en =CONTAR.SI(E15:E1000;”BACALAO”) + =CONTAR.SI(E15:E1000;”MERLUZA”)
    Todo esto fundiendo el resultado en una celda. Es decir, la suma de los que eligieron bacalao y merluza. ¿Como se hace?

    Responder
    1. Moisés Ortíz Autor

      Hola Abraham, solo debes sumar el resultado de ambas funciones en una misma celda:
      =CONTAR.SI(E15:E1000;”BACALAO”) + CONTAR.SI(E15:E1000;”MERLUZA”)

      Responder
  64. Washington

    Necesito saber cuantas celdas tengo con datos, las que están en blanco que no me las cuente. Me podrías ayudar de como hacer la fución.
    Muchas gracias.

    Responder

Deja un comentario

Tu dirección de correo electrónico no será publicada. Los campos necesarios están marcados *

Puedes usar las siguientes etiquetas y atributos HTML: <a href="" title=""> <abbr title=""> <acronym title=""> <b> <blockquote cite=""> <cite> <code> <del datetime=""> <em> <i> <q cite=""> <strike> <strong>